Standard 3rd person controls?

;Before anything takes place in your game:

VectorPivot = CreatePivot()
EntityParent(VectorPivot, Camera, False) ;False makes the pivot snap to the camera's orientation and position automatically.

;You need a previously declared constant such as "pSpeed#" or something like that. It's the Player's movement speed.

;This snippet needs to run AFTER you pointed your camera to the player.

RotateEntity(VectorPivot, 0, EntityYaw(VectorPivot,True) , 0, True)

TFormVector(KeyRight-KeyLeft , 0, KeyUp-KeyDown, VectorPivot, 0)

;The KeyRight, KeyLeft and the other variables are simple key states: KeyRight = KeyDown(203). 
;Makes it easier to handle.

AlignToVector(Player, TFormedX(), 0, TFormedZ(), 3) 
MoveEntity(Player, 0, 0, pSpeed)

;Replace the AlignToVector line from the snippet I showed previously with this:

TFormPoint(TFormedX(),0,TFormedZ(),Player,0)
PositionEntity(PlayerOrientation,TFormedX(),TFormedY(),TFormedZ(),True)
TurnEntity(Player,0,DeltaYaw(Player,PlayerOrientation),0,True)

If KeyDown(200)
KeyRight = KeyDown(200)
EndIf

KeyRight = KeyDown(200)

dx#=EntityX( target,True )-EntityX( camera )
		dy#=EntityY( target,True )-EntityY( camera )
		dz#=EntityZ( target,True )-EntityZ( camera )
	    TranslateEntity camera,dx*.3,dy*.1,dz*.3

If ((EntityDistance(camera,target)<2) or (EntityDistance(camera,target)>5))
dx#=EntityX( target,True )-EntityX( camera )
		dy#=EntityY( target,True )-EntityY( camera )
		dz#=EntityZ( target,True )-EntityZ( camera )
	    TranslateEntity camera,dx*.3,dy*.1,dz*.3
End If

 use brackets around the word "code" and then "/code" 

Graphics3D 800,600,1,2  ;Set up graphics

;Create global pivot variables, two are for the pivots and two are for the positions
Global piv1
Global piv2
Global pivx
Global pivz

Global camera=CreateCamera()  ;Create a camera and make sure it is global

light = CreateLight()  ;Create a light to give a sense of depth, looks better
PositionEntity light,10,10,10

PositionEntity camera,0,10,-5  ;Move the camera up and back a little, just to help with depth perception

Function CreateCharacter()  ;Call this function to set up your 3rd person camera and create a player

	piv1 = CreatePivot() ;create two pivots for 3rd person camera
	piv2 = CreatePivot()

	EntityParent piv2,piv1  ;assign 2nd pivot to have a parent of the 1st one, needs this line for relative positioning
	
	character = CreateCube() ;create or load your character here
	ball = CreateSphere()  ;I've created a ball to represent the front of the character
	MoveEntity ball,0,0,1  ;Position the ball to the front of the cube
	EntityParent ball,character  ;just tells the ball to follow wherever the cube goes
	Return character  ;IMPORTANT! Without this line, you've created a character, but the character is not saved as "player"

End Function

Global player=CreateCharacter()  ;creates the player from above and saved it as "player"

PointEntity light,player  ;just point the light at the player

While Not KeyDown(1)  ;main loop
	Update3rdPersonCamera()  ;update the camera
	PositionEntity camera,EntityX(camera),10,EntityZ(camera)  ;this just ensures that the height of the camera doesn't change
	RenderWorld  ;update everything
	Text 0,0,"player yaw: " + EntityYaw(player) ;get information to the screen
	Text 0,20,"player x: " + EntityX(player)
	Text 0,40,"player y: " + EntityY(player)
	Text 0,60,"player z: " + EntityZ(player)
	Text 0,100,"camera yaw: " + EntityYaw(camera)
	Text 0,120,"camera x: " + EntityX(camera)
	Text 0,140,"camera y: " + EntityY(camera)
	Text 0,160,"camera z: " + EntityZ(camera)
	Flip
Wend

Function Update3rdPersonCamera()

	PointEntity camera,player ;Point the camera at the character
	
	If KeyDown(75) ;If we push the number pad left key
		MoveEntity camera,-.5,0,.05 ;Effectively orbits the camera left around the character
	EndIf
	
	If KeyDown(77) ;If we push the number pad right key
		MoveEntity camera,.5,0,.05 ;Effectively orbits the camera right around the character
	EndIf
	
	If KeyDown(200) ;If we push the up arrow
		pivz = 50 ;Set our global variable of pivz to 50
	EndIf
	
	If KeyDown(208) ;If we push the down arrow
		pivz = -50 ;Set our global variable of pivz to -50
	EndIf
	
	If KeyDown(203) ;If we push the left arrow
		pivx = -50 ;Set our global variable of pivx to -50
	EndIf
	
	If KeyDown(205) ;If we push the right arrow
		pivx = 50 ;Set our global variable of pivx to 50
	EndIf
	
	If Not KeyDown(200) ;If the up arrow is release
		If Not KeyDown(208) ;and if the down arrow is released
			pivz = 0 ;Reset the local "z" position of the 2nd pivot
		EndIf
	EndIf
	
	If Not KeyDown(203) ;If the left arrow is release
		If Not KeyDown(205) ;and if the right arrow is released
			pivx = 0 ;Reset the local "x" position of the 2nd pivot
		EndIf
	EndIf
	
	RotateEntity piv1,0,EntityYaw(camera),0
	;Rotate the 1st pivot to match
	;the camera's current rotation
	
	PositionEntity piv1,EntityX(player),EntityY(player),EntityZ(player) 
	;Position the 1st pivot exactly
	;where your character is
	
	PositionEntity piv2,pivx,EntityY(player),pivz,False
	
	If EntityDistance(piv2,player) >= 10 ;Don't rotate the character unless
	;unless the distance between the
	;character and piv2 is greater than
	;or equal to 10. Otherwise the 
	;character spazzes out when no
	;button is pressed.
	
	pitch = EntityPitch(player) ;Get the pitch rotation of the model
	
	roll = EntityRoll(player) ;Get the roll rotation of the model
	
	PointEntity player,piv2 ;Point the character in the correct direction
	
	RotateEntity player,pitch,EntityYaw(player),roll
	;This line simply corrects any
	;unintended rotation other than
	;on the y-axis. x-axis and z-axis
	;can tilt the character is strange
	;ways.
	MoveEntity player,0,0,1 ;make the character walk or move in the
	;direction that he is facing
	pitch = EntityPitch(camera) ;get the temporary rotation of the camera
	
	yaw = EntityYaw(camera) ;get the temporary rotation of the camera
	
	roll = EntityRoll(camera) ;get the temporary rotation of the camera
	
	RotateEntity camera,EntityPitch(player),EntityYaw(player),EntityRoll(player)
	;The above line rotates the camera to match the rotation of the player
	
	MoveEntity camera,0,0,1
	;Move the camera at the same pace and direction as the player moved
	
	RotateEntity camera,pitch,yaw,roll ;Return the camera back to it's original
	;rotation. This allows for cool camera
	;tricks such as pushing right while still
	;pointing at the player (a.k.a. sweeping)
	
		
	EndIf
	
	If EntityDistance(player,camera) > 100
		PointEntity camera,player
		MoveEntity camera,0,0,5
	EndIf

	If EntityDistance(player,camera) < 10
		PointEntity camera,player
		MoveEntity camera,0,0,-5
	EndIf

End Function

;Rob Merrick's 3rd Person Camera Test and Demo.

;This program sets up a character figure, a terrain, and trees, and 
;demonstrates the use of a 3rd person camera. I use this similar routine
;in a zelda game that I have designed. Note that the zelda game was only
;made for "shits and giggles", and I do not make any profit from the
;copyrighted material.

;Virtually every line is commented to ensure that whoever reads it can clearly understand
;what's happening.

;This routine is still a fairly inefficient one. I have taken code that is years old and
;written it in a way to give example of how a 3rd person camera works.
;It is based on the commands of relative positioning from the blitz3d engine.

;This code can be re-written to support joystick commands and other forms of input, and it
;was originally design to do so. For more information, contact me and I will provide
;other variations of this code.

;I consider this code to be open-source, and I do not require any credit that this code may
;appear in. I'm sure I'm not the first person to come up with this idea, but if you do
;desire to add in my credit, I will go by the name of Rob Merrick.

;For a complete version of my game demo, visit www.merrickproductions.com/videogame.htm.

;Thank you for your interest, and enjoy!


;Program Setup
;--------------------------------------------------------------------------------------------------------------------------

Graphics3D 800,600,1,2           ;Set up graphics

SetBuffer BackBuffer()           ;Set up double buffer. Makes smoother graphics.

Global piv1                      ;Create global pivot variables, two are for
Global piv2                      ;the pivots and two are for the positions.
Global pivx
Global pivz

Global camera=CreateCamera()     ;Create a camera and make sure it is global

Global plane = CreatePlane()     ;Let's Create a little ground for our player.
EntityColor plane,125,100,50     ;Give the ground a brown color
PositionEntity plane,0,-1,0      ;Move the ground down a little bit

CreateRandomTerrain()            ;Call a function to generate some "trees"

light = CreateLight()            ;Create a light to give a sense of depth, looks better
PositionEntity light,10,10,10    ;Move the light to give some shading effects

PositionEntity camera,0,10,-5    ;Move the camera up and back a little, just to help with depth perception

Global player=CreateCharacter()  ;Call a funtion to create the main character and save it as "player"

PointEntity light,player         ;just point the light at the player

;--------------------------------------------------------------------------------------------------------------------------
;End the Program Setup


;Start the Main Loop
;--------------------------------------------------------------------------------------------------------------------------


While Not KeyDown(1)                                          ;main loop

	Update3rdPersonCamera()                                   ;update the camera-This should be towards the top of the loop to avoid problems
	PositionEntity camera,EntityX(camera),10,EntityZ(camera)  ;this just ensures that the height of the camera doesn't change
	RenderWorld                                               ;update everything, get new positions and prepare to draw to the screen
	Text 0,0,"player yaw: " + EntityYaw(player)               ;get information to the screen
	Text 0,20,"player x: " + EntityX(player)
	Text 0,40,"player y: " + EntityY(player)
	Text 0,60,"player z: " + EntityZ(player)
	Text 0,100,"camera yaw: " + EntityYaw(camera)
	Text 0,120,"camera x: " + EntityX(camera)
	Text 0,140,"camera y: " + EntityY(camera)
	Text 0,160,"camera z: " + EntityZ(camera)
	Text 300,0,"3rd Person Camera Control:"                   ;Give controls information to the screen
	Text 300,20,"Push the arrow keys to point"
	Text 300,40,"the character in that direction."
	Text 300,60,"Push the pad left and right arrows"
	Text 300,80,"to orbit that camera in that direction."
	Flip                                                      ;The actual drawing process for blitz. Flipping the double buffer
	
Wend

End                                                           ;When you leave the main loop, always call this command.

;--------------------------------------------------------------------------------------------------------------------------
;End the Main Loop


;Start the Functions List
;--------------------------------------------------------------------------------------------------------------------------

Function CreateCharacter()               ;Call this function to set up your 3rd person camera and create a player

	piv1 = CreatePivot()                 ;create two pivots for 3rd person camera
	piv2 = CreatePivot()

	EntityParent piv2,piv1               ;assign 2nd pivot to have a parent of the 1st one, needs this line for
										 ;relative positioning
	
	character = CreateCube()             ;create or load your character here
	ball = CreateSphere()                ;I've created a ball to represent the front of the character
	MoveEntity ball,0,0,1                ;Position the ball to the front of the cube
	EntityParent ball,character          ;just tells the ball to follow wherever the cube goes
	Return character                     ;IMPORTANT! Without this line, you've created a character, but the character
										 ;is not saved as "player"

End Function

Function Update3rdPersonCamera()         ;Call this function to update your 3rd person camera

	PointEntity camera,player            ;Point the camera at the character
	
	If KeyDown(75)                       ;If we push the number pad left key
		MoveEntity camera,-.5,0,.05      ;Effectively orbits the camera left around the character
	EndIf
	
	If KeyDown(77)                       ;If we push the number pad right key
		MoveEntity camera,.5,0,.05       ;Effectively orbits the camera right around the character
	EndIf
	
	If KeyDown(200)                      ;If we push the up arrow
		pivz = 50                        ;Set our global variable of pivz to 50
	EndIf
	
	If KeyDown(208)                      ;If we push the down arrow
		pivz = -50                       ;Set our global variable of pivz to -50
	EndIf
	
	If KeyDown(203)                      ;If we push the left arrow
		pivx = -50                       ;Set our global variable of pivx to -50
	EndIf
	
	If KeyDown(205)                      ;If we push the right arrow
		pivx = 50                        ;Set our global variable of pivx to 50
	EndIf
	
	If Not KeyDown(200)                  ;If the up arrow is release...
		If Not KeyDown(208)              ;and if the down arrow is released
			pivz = 0                     ;Reset the local "z" position of the 2nd pivot
		EndIf
	EndIf
	
	If Not KeyDown(203)                  ;If the left arrow is release...
		If Not KeyDown(205)              ;and if the right arrow is released
			pivx = 0                     ;Reset the local "x" position of the 2nd pivot
		EndIf
	EndIf
	
	RotateEntity piv1,0,EntityYaw(camera),0
	                                     ;Rotate the 1st pivot to match
	                                     ;the camera's current rotation
	
	PositionEntity piv1,EntityX(player),EntityY(player),EntityZ(player) 
	                                     ;Position the 1st pivot exactly
	                                     ;where your character is
	
	PositionEntity piv2,pivx,EntityY(player),pivz,False
	                                     ;Position the 2nd pivot in a 
	                                     ;relative spot to your character
	                                     ;with the vector of the variables
	                                     ;pivx and pivz added to the x and
	                                     ;z values. Note that the "False"
	                                     ;command is what makes this whole
	                                     ;function work correctly.
	
	If EntityDistance(piv2,player) >= 10 ;Don't rotate the character unless
		                                 ;the distance between the
		                                 ;character and piv2 is greater than
		                                 ;or equal to 10. Otherwise the 
		                                 ;character spazzes out when no
		                                 ;button is pressed.
		
		pitch = EntityPitch(player)      ;Get the pitch rotation of the model
		
		roll = EntityRoll(player)        ;Get the roll rotation of the model
		
		PointEntity player,piv2          ;Point the character in the correct direction
		
		RotateEntity player,pitch,EntityYaw(player),roll
		                                 ;This line simply corrects any
		                                 ;unintended rotation other than
		                                 ;on the y-axis. x-axis and z-axis
		                                 ;can tilt the character is strange
		                                 ;ways.
		
		MoveEntity player,0,0,1          ;make the character walk or move in the
		                                 ;direction that he is facing
		
		pitch = EntityPitch(camera)      ;get the temporary rotation of the camera
		
		yaw = EntityYaw(camera)          ;get the temporary rotation of the camera
		
		roll = EntityRoll(camera)        ;get the temporary rotation of the camera
		
		RotateEntity camera,EntityPitch(player),EntityYaw(player),EntityRoll(player)
		                                 ;The above line rotates the camera to match
									     ;The rotation of the player
		
		MoveEntity camera,0,0,1
		                                 ;Move the camera at the same pace and direction
										 ;as the player moved
		
		RotateEntity camera,pitch,yaw,roll 
		                                 ;Return the camera back to it's original
		                                 ;rotation. This allows for cool camera
		                                 ;tricks such as pushing right while still
		                                 ;pointing at the player (a.k.a. sweeping)
		
		
	EndIf
	
	;Now let's do some camera distance checking and correct any problems
	
	If EntityDistance(player,camera) > 100 ;If the camera is too far away...
		PointEntity camera,player          ;Point the camera at the player
		MoveEntity camera,0,0,5            ;Move the camera 5 units closer to the player
	EndIf

	If EntityDistance(player,camera) < 10  ;If the camera is too close...
		PointEntity camera,player          ;Point the camera at the player
		MoveEntity camera,0,0,-5           ;Move the camera 5 units further from the player
	EndIf

End Function                               ;End the Function



Function CreateRandomTerrain()                               ;Call this function to generate trees.

	For x = 0 To 1000                                        ;Do this block 1000 times
		cone = CreateCone()                                  ;Create a cone
		EntityColor cone,0,125,0                             ;Color it mid tone green
		PositionEntity cone,Rand(-500,500),0,Rand(-500,500)  ;Position it on a random x and z location
	Next                                                     ;Tell blitz that this is the end of the block.

End Function                                                 ;End the Function

;------------------------------------------------------------------------------------------------------------
;End the Functions List