Screen tearing or double image

Blitz3D Forums/Blitz3D Beginners Area/Screen tearing or double image

fox95871

(Posted 2010) [#1]

Hi, I've been considering using Flip 0 for my games. I know I'm supposed to hate the screen tearing, but compared to the double image of Flip 1, I really don't. What do you all think? In particular, are there any other problems with using Flip 0, and as far as Flip 1 is there any way to get rid of the double image effect? Please try my code to see what I mean.

Graphics3D 640,480,32,1
SetBuffer BackBuffer()
AntiAlias     0
Dither        0
WireFrame     0
AutoMidHandle 0
blitz=LoadFont("blitz",10,1,0,0)
SetFont blitz
SeedRnd MilliSecs()
Const fps=30
period=1000/fps
time=MilliSecs()-period
elapsed%=0
ticks%=0
tween#=0
rt%=0
Color 100,100,100
Global rendertween $=""
Global flipstate   %=0
Global speed       #=0
Global         camera=CreateCamera()
PositionEntity camera,0,0,-10
CameraZoom     camera,1.6
CameraClsColor camera,10,10,10
CameraRange    camera,.1,10000
Global      cube=CreateCube()
ScaleEntity cube,2,2,2
While Not KeyHit(1)
Cls



;on for tweened rendering
;------------------------------
Repeat
elapsed=MilliSecs()-time
Until elapsed
ticks=elapsed/period
tween#=Float(elapsed Mod period)/Float(period)
For rt=1 To ticks
time=time+period
If rt=ticks
CaptureWorld
EndIf
RendertweenMovingControl()
MovingEffects()
UpdateWorld
Next
RenderWorld tween
rendertween="on"



;on for normal rendering
;------------------------------
;UpdateWorld
;RenderWorld
;NormalMovingControl()
;MovingEffects()
;rendertween="off"



Flipswitch()
DebugText()
Flip flipstate
Wend
End
Function Flipswitch()
If KeyHit(57) flipstate=1-flipstate
End Function
Function RendertweenMovingControl()
If     KeyDown(203):speed=-.2
ElseIf KeyDown(205):speed=+.2
Else                speed=0
EndIf
End Function
Function NormalMovingControl()
Select flipstate
Case 0
If     KeyDown(203):speed=-.014
ElseIf KeyDown(205):speed=+.014
Else                speed=0
EndIf
Case 1
If     KeyDown(203):speed=-.17
ElseIf KeyDown(205):speed=+.17
Else                speed=0
EndIf
End Select
End Function
Function MovingEffects()
TranslateEntity cube,speed,0,0
End Function
Function DebugText()
Text 0,00,"Controls: left right and space"
Text 0,15,"rendertween " +rendertween
Text 0,30,"  flipstate " +flipstate
End Function
















;

Sorry I have so many posts today, I don't get to use the internet very often.

fox95871

(Posted 2010) [#2]

Anyone? This is one I really need answered if someone wouldn't mind testing it.

Yasha

(Posted 2010) [#3]

What kind of double image effect? I don't see anything different between Flip 0 and Flip 1 in that code...?

lo-tekk

(Posted 2010) [#4]

There's no best solution, the only thing to consider early on is, whether the usage of tweening or delta timing. If you decided for one or the other stick to it. Just develop your game. There are ways to reduce texture tearing and such, but it also depends upon the target system and driver settings. It also differs between fullscreen and windowed. You may also look into the vwait command. Just use the method that looks best for your game.

_Skully

(Posted 2010) [#5]

On MAC's flip 0 causes tearing for sure.. on PC's it seems to be occasional but I used to use flip 0 all the time until I realized that the processor cooks real hot when you don't frame limit your code.

I discovered that when I ran some code on my laptop procedurally and didn't frame limit it... it caused my laptop to overheat!

lo-tekk

(Posted 2010) [#6]

the processor cooks real hot when you don't frame limit your code.

It's also good practice to add some delay in every loop, so you don't eat up all processor time. A simple delay 1 would do the trick.

fox95871

(Posted 2010) [#7]

Thanks! Lo-tekk and Skully, is frame limiting the same thing as render tweening? And what's delta timing? Yasha, the double image, visible with the render tween either on or off in my code, is where it looks like there's a second box trailing just after the first one when you move it, on my computer anyway. With Flip 0 it's gone, replaced by a barely noticeable screen tearing.

Any other information about the overheating problem of Flip 0, and if other people are able to see the double image of Flip 1 on their computers would be greatly appreciated.

lo-tekk

(Posted 2010) [#8]

Here's another one using tweening and should give some time back to the os. As you can see it's almost the same as yours except the vwait command used.

Graphics3D 800,600

Global light=CreateLight()
Global Camera=CreateCamera()
Global Cube=CreateCube()

PositionEntity light,0,50,-50
PositionEntity Camera,0,0,-5

Const GameUPS=60 ; Updates per second
Local Period=1000/GameUPS 
Local FrameTime=MilliSecs()-Period

Local Tween#, Ticks,i,Remaining,StartTime,Elapsed

While Not KeyHit(1)
	
	StartTime = MilliSecs()
	
	Repeat
		Elapsed=MilliSecs()-FrameTime
	Until Elapsed
	
	Ticks=Elapsed / Period
	Tween=Float(Elapsed Mod Period)/Float(Period)
	
	For i=1 To Ticks
		FrameTime=FrameTime+Period
		If i=Ticks Then
			CaptureWorld
		End If
		UpdateGame()
		UpdateWorld
	Next
	RenderWorld Tween
	
	Remaining = Period - (MilliSecs() - StartTime)
	If Remaining > 1 Then 
		Delay (Remaining-1) ; Free some CPU time
	End If
	
	VWait 1
	Flip 0
	
Wend

End

Function UpdateGame()
	
	Local speed#=(KeyDown(205)-KeyDown(203))*0.1
	TranslateEntity Cube,speed,0,0
	
End Function