Text Entry

Blitz3D Forums/Blitz3D Beginners Area/Text Entry

_PJ_	(Posted 2010) [#1]

I had a text entry routine in another project and I have been trying to make it less specific and more 'portable'.

However, Ive broken it somewhere and I can't understand where...
The cursor always moves BACKWARDS on Ascii input or backspace, whilst the cursors etc. and Delete still work correctly.

Can anyone see what's wrong here?

Here's the crucial parts of the code, with comments, placed in a runnable example

Graphics 800,600,32,6
SetBuffer BackBuffer()

; DECLARATION - PLACE THESE OUTSIDE OF AND BEFORE YOUR LOOP
Global txt_LastKeyDelay=MilliSecs()
Global txt_EnteredText$=""; This is the Entered text
Global txt_TextEntryMode=True; Set this to True or False to enable/disable text entry mode
Global txt_Current_TextCursor
Global txt_PointerMode=True;	Will be used for determining Caret and storing the status of ShowPointer/idePointer
Const txt_KeyRepeatDelay=85;	Delay between keypress repetition

While Not KeyDown(1)
	
; TEXT INPUT MODE CHECK - PLACE THIS WITHIN YOUR LOOP
If (txt_TextEntryMode)
	If (txt_PointerMode)
		HidePointer
		txt_PointerMode=False
		;Here's where Caret control will come in later
	End If
	txt_EditText
End If
Cls
txt_DrawTextEntry(txt_EnteredText$,100,100,True,False)
Flip

Wend

; FUNCTIONS - PLACE THESE ELSEWHERE IN YOUR CODE
Function txt_DrawTextEntry(txt_sText$,txt_X,txt_Y,txt_CentreX=False,txt_CentreY=False)
	;Use this to display the text
	
	;Note txt_sText$ is used as a Local parameter, rather than rely on the Global txt_EnteredText$. This will not be necessary with a better cursor implementation.
	
	txt_sText$=Replace(txt_sText,"_"," ")										;Temporary use until a better cursor/Caraet is added
	
	If (txt_TextEntryMode)
		Local txt_Pre=txt_Current_TextCursor
		Local txt_Suf=txt_Current_TextCursor
		
		Local txt_sSufT$=""
		Local txt_sPreT$=""
		
		If (txt_Pre<1)
			txt_sSufT$=txt_sText$
		Else
			If txt_Suf>Len(txt_sText$)
				txt_sPreT$=txt_sText$
			Else
				txt_sSufT$=Right(txt_sText$,Len(txt_sText$)-txt_Suf)
				txt_sPreT$=Left(txt_sText$,txt_Pre)
			End If
		End If
		txt_sText$=txt_InsertTextAtCursor(txt_sText,"_")							;Temporary use until a better cursor/caret is added
		txt_sText$=Replace(txt_sText$,"__","_")										;Temporary use until a better cursor/caret is added
	End If
	Text txt_X,txt_Y,txt_sText,txt_CentreX,txt_CentreY
End Function

Function txt_EditText()
	If ((MilliSecs()-txt_LastKeyDelay)<txt_KeyRepeatDelay) Then Return
	txt_LastKeyDelay=MilliSecs()
	If (KeyDown(28)) Or (KeyDown(156))											;RETURN/ENTER
		txt_TextEntryMode=False
		If (Not(txt_PointerMode))
			ShowPointer
			txt_PointerMode=True
																				;Caret Control will go here
		End If
		Return
	End If
	Local txt_ASCII=GetKey()
	;If (KeyDown(46))
	;	If (KeyDown(29)) Or (KeyDown(157))
	;		;																	;Paste text
	;		;txt_InsertText()
	;		;
	;		Return
	;	End If
	;End If
	;If (KeyDown(47))
	;	If (KeyDown(29)) Or (KeyDown(157))
	;		;		
	;		;
	;		Return
	;	End If
	;End If
	If ((KeyDown(211)) And (txt_Current_TextCursor<(Len(txt_EnteredText))))
																				;Backspace
		txt_EnteredText=txt_InsertTextAtCursor(txt_EnteredText,"",False,True)
		Return
	End If
	If (KeyDown(14) And (txt_Current_TextCursor>0))
		txt_EnteredText=txt_InsertTextAtCursor(txt_EnteredText,"",True,False)	;Delete
		Return
	End If
	
	If ((KeyDown(203)) And (txt_Current_TextCursor>0)) Then txt_Current_TextCursor=txt_Current_TextCursor-1																								; Arrow Key LEFT (Number Pad Arrow Keys to come soon)
	If ((KeyDown(205)) And (txt_Current_TextCursor<Len(txt_EnteredText))) Then txt_Current_TextCursor=txt_Current_TextCursor+1																			; Arrow Key RIGHT (Number Pad Arrow Keys to come soon)
	
	If (KeyDown(207)) Then txt_Current_TextCursor=Len(txt_EnteredText)																																; END Control
	If (KeyDown(199)) Then txt_Current_TextCursor=0																																						; HOME Control
	
	If KeyDown(57) Then txt_InsertTextAtCursor(txt_EnteredText," ")																																								;SPACE
	
	If (Not(txt_ASCII)) Then Return
	If (txt_ASCII>32) And (txt_ASCII<127)										;Standard text
		Local txt_sText$=Chr$(txt_ASCII)
		If (KeyDown(42) Or KeyDown(54))											;(Due To a B3D/Windows bug, Caps Shift does Not correctly change the Case For ASCII results)
																				;CapsLock checking To follow
			If ((txt_ASCII>96 And txt_ASCII<122)) Then txt_sText$=Upper$(txt_sText$)
		End If
		txt_EnteredText$=txt_InsertTextAtCursor(txt_EnteredText$,txt_sText$)
		Return
	End If	
End Function

Function txt_InsertTextAtCursor$(txt_TextString$,txt_sText$="",txt_ModifyPre=0,txt_ModifySuf=0)
	Local txt_sTextPrefix$=Left(txt_TextString,(txt_Current_TextCursor-txt_ModifyPre))
	Local txt_sTextSuffix$=Right(txt_TextString,Len(txt_TextString)-(txt_Current_TextCursor+txt_ModifySuf))
	txt_TextString$=txt_sTextPrefix+txt_sText+txt_sTextSuffix
	Return txt_TextString$
End Function

BoneStan

(Posted 2010) [#2]

The txt_TextString$ begun with the left part of the string.
But now works Delete incorrect.

Function txt_InsertTextAtCursor$(txt_TextString$,txt_sText$="",txt_ModifyPre=0,txt_ModifySuf=0)
	Local txt_sTextPrefix$=Left(txt_TextString,(txt_Current_TextCursor-txt_ModifyPre))
	Local txt_sTextSuffix$=Right(txt_TextString,Len(txt_TextString)-(txt_Current_TextCursor+txt_ModifySuf))

	;The cursor always moves BACKWARDS, Delete still work correctly.
	;txt_TextString$=txt_sTextPrefix+txt_sText+txt_sTextSuffix
	
;The cursor moves forwards but delete begins from the left position.
txt_TextString$=txt_sTextSuffix+txt_sText+txt_sTextPrefix
	
	Return txt_TextString$
End Function

_PJ_	(Posted 2010) [#3]

Exchanging True/False should fix that, however it seems like a 'kludge' rather than a fix.

Not that I'm ungrateful, Stan, I do appreciate your help, but I am still interested to know what's wrong with the code and how to fix it properly.

Midimaster

(Posted 2010) [#4]

I think it it missing a

txt_Current_TextCursor=txt_Current_TextCursor+1

in the case, when a new real ASCII-character is added to the string, or? The string gets longer and the cursor should be behind the new sign afterwards.

If (txt_ASCII>32) And txt_ASCII<127)
   Local txt_sText$=Chr$(txt_ASCII)
      If (KeyDown(42) Or KeyDown(54))
         If ((txt_ASCII>96 And txt_ASCII<122)) Then
            txt_sText$=Upper$(txt_sText$)
		 End If
         txt_EnteredText$=txt_InsertTextAtCursor(txt_EnteredText$,txt_sText$)
         txt_Current_TextCursor=txt_Current_TextCursor+1
         Return
      End If
....

But you have a second problem. the BACKSPACE is not working correct in your sample!