minimize window to taskbar?

Blitz3D Forums/Blitz3D Beginners Area/minimize window to taskbar?

Guy Fawkes

(Posted 2009) [#1]

hi all. can someone please translate this minimize program to taskbar tray from blitzplus, to blitzbasic?

;
; FILENAME: TaskBarTrayExample.bb
;		    Copyright 2003, Kevin Poole.
; 		                    kevin.poole@...

; these belong to .dll for using the tray icon.
Const NIM_ADD = $0
Const NIM_MODIFY = $1
Const NIM_DELETE = $2
Const NIF_MESSAGE = $1
Const NIF_ICON = $2
Const NIF_TIP = $4
Const WM_LBUTTONDBLCLK = $203
Const WM_LBUTTONDOWN = $201
Const WM_LBUTTONUP = $202
Const WM_RBUTTONDBLCLK = $206
Const WM_RBUTTONDOWN = $204
Const WM_RBUTTONUP = $205
Const WM_MOUSEMOVE = $200
Const PK_TRAYICON = $401+1 ;$401 

; general windows messages
Const WM_USER = $400
Const WM_COMMAND = $111

Const GWL_WNDPROC = (-4)

; window and gadgets for this example. 
Global window,hide_button


; when app in tray its set to 1.
Global IN_Tray=1

; the window's address.
Global hWnd

; unused! will be for error checking.
Global taskbar

; holds a bank containg the icons data.
Global IconData

; holds a bank for reiceving messeges from the taskbar icon.
Global events=CreateBank(256)

; to display when over sys icon.
Global tool_tip$="TaskBar Tray Example"+Chr$(0)
	
; the icon to display.
file_icon$="TaskBarTrayExample.ico"


; add a popup menu to the taskbar icon.
Add_Icon_Menu(1,"Show TaskBar Window")
Add_Icon_Menu(2,"About TaskBar .dll")

; add a menu devide.
Add_Icon_Menu(0,"")

; add a popup menu to the taskbar icon.
Add_Icon_Menu(3,"See TaskBar Commands")
Add_Icon_Menu(4,"Quit")


; should we go to taskbar?
If IN_Tray=1 Then

	; create example window.	
	create_window()
					
	; set focus to the taskbar, this is needed to recive events.
	FocusTaskBar(hWnd,0)
	Add_Tray_Icon(tool_tip$,hWnd,file_icon$)
	Modify_Tray_Icon(NIM_ADD,"") 

	; hide the window.	
	HideGadget window

	; wait for events from the taskbar.
	sys_tray()

Else

	; create example window.
	create_window()
	
EndIf

; the example main event loop.
While WaitEvent()<>$803
	
	; get the type of event.
	event_type=EventID()
	Select event_type

		;was it a gadget action event?
		Case $401
	
			; select the gadget that made the event.
			Select EventSource()
	
				Case hide_button
								
					; set for taskbar icon and get the window address.
					IN_Tray=1
					
					; set focus to the taskbar, this is needed to recive events.
					FocusTaskBar(hWnd,0)
					Add_Tray_Icon(tool_tip$,hWnd,file_icon$)
					Modify_Tray_Icon(NIM_ADD,"") 
					
					; modify the icon tool text.
					Modify_Tray_Icon(NIM_MODIFY,"Tool text as been modifyed!"+Chr$(0))	
								
					; hide the example window.
					HideGadget window
					
					; wait for events from the taskbar.
					sys_tray()
							
			End Select


	End Select
	
	
	
Wend

; cleanup and end.
clean_up()

Function clean_up()

	; free used gadgets.
	FreeGadget hide_button 
	FreeGadget window 

	; remove the icon and delete its menu.
	Modify_Tray_Icon(NIM_DELETE,"")
	DeleteIconMenu()
	
	; end
	End
End Function

;
; wait for events from the taskbar.
;

Function sys_tray()

; clear any old task tray icon events.
PokeInt events,0,0

; wait for events from the taskbar.
While IN_Tray=1
	
	; do we have any events.
	Select PeekInt(events,0)
	
		Case 1 ; Icon left button double click.
			
			; set the status of the taskbar.
			IN_Tray=0
			
			; show the example window.
			ShowGadget window
			
			; delete the icon from the taskbar tray.	
			Modify_Tray_Icon(NIM_DELETE,"")
									
			Return
			
		Case 2 ; Icon right click.

			Select TaskBarMenuEvent(hWnd)

				Case 1 ; Show TaskBar Window.	
				
					; set the status of the taskbar.
					IN_Tray=0
			
					; show the example window.
					ShowGadget window
					
					; delete the icon from the taskbar tray.	
					Modify_Tray_Icon(NIM_DELETE,"")
				
					Return

				Case 2 ; About TaskBar .dll.

					create_window_about()
					
					; refocus taskbar icon, show window menu not selected.
					FocusTaskBar(hWnd,0)
					
				Case 3 ; See TaskBar Commands.			

					create_window_commands()
				
					; refocus taskbar icon, show window menu not selected.
					FocusTaskBar(hWnd,0)
		
				Case 4 ; quit menu.
				
				; cleanup and end.
				clean_up()
			Default
					; refocus taskbar icon, there was no menu selected.
					FocusTaskBar(hWnd,0)
			End Select
		
		Case 3,4,5,6,7 ; other menu events, that are not used.       
		
			; refocus taskbar icon, show window menu not selected.
			If IN_Tray=1 Then FocusTaskBar(hWnd,0)				
			
	End Select
	
	; store taskbar icon event.	
	PokeInt events,0,TaskBarEvent(hWnd,0,0,0,0)
	
Wend		

End Function

;
; add a menu items to the taskbar icon. 
;

Function Add_Icon_Menu(menuID,menuTXT$)

	menuTXT$=menuTXT$+Chr$(0)
	
	; add new menu item to taskbar icon.
	added=AddIconMenu(menuID,menuTXT$)

End Function

;
; used to modify the taskbar icon.
;

Function Modify_Tray_Icon(modify,new_tip$)

	; we want to modify the tool tip string data.
	If new_tip$<>"" Then
		
		; get the length of the tool tip.
		strlen = Len(new_tip$)
		
		; resize the bank to fit new tool tip.
		ResizeBank IconData,24+strLen
		
		; modify the tool tip text.
		For strlen=1 To Len(new_tip$)
			PokeByte IconData,24+strlen-1,Asc(Mid$(new_tip$,strlen,1))
		Next
		
	EndIf
	
	;modify the taskbar icon.
	taskbar=TaskBarIcon(modify, IconData)
	
End Function

; tool_tip$ - tool tip string.
; hWin      - the window that recives messages from the tray icon.
; icon$     - filename of icon to use.
	
Function Add_Tray_Icon(tip$,hWnd,icon$)

	; fill the bank up with taskbar tray icon details
	IconData=CreateBank(24+Len(tip$))
	PokeInt IconData,00,BankSize(IconData)
	PokeInt IconData,04,hWnd
	PokeInt IconData,08,1
	PokeInt IconData,12,NIF_ICON Or NIF_TIP Or NIF_MESSAGE 
	PokeInt IconData,16,100
	PokeInt IconData,20,LoadTaskIcon(hWnd,icon$,0)

	; now fill the rest with the tool tip text.
	For strlen=1 To Len(tip$)
		PokeByte IconData,24+strlen-1,Asc(Mid$(tip$,strlen,1))
	Next
		
End Function


;
; example window.
;
Function create_window()

; create example window.
window = CreateWindow("SystemTray Example",389,290,243,128,Desktop(),1)
hide_button = CreateButton("Close To System Tray",41,71,154,20,window,0)
SetGadgetLayout hide_button,1,0,1,0

hWnd=QueryObject(window,1)

End Function

; ----Function Begins----
Function create_window_about()

window_about = CreateWindow("About ",277,219,265,157,window,1)
window_about_done = CreateButton("Done",77,98,100,20,window_about,0)
SetGadgetLayout window_about_done,1,0,1,0
window_about_label1 = CreateLabel("TaskBarTrayExample",76,21,124,20,window_about,0)
SetGadgetLayout window_about_label1,1,0,1,0
window_about_label2 = CreateLabel("Copyright 2003, Kevin Poole.",57,46,142,17,window_about,0)
SetGadgetLayout window_about_label2,1,0,1,0
window_about_label3 = CreateLabel(\"kevin.poole@...)
SetGadgetLayout window_about_label3,1,0,1,0


While done=0 

	; 
	WaitEvent()

	; get the type of event.
	event_type=EventID()
	Select event_type

		;was it a gadget action event?
		Case $401
	
			; select the gadget that made the event.
			Select EventSource()
	
				Case window_about_done
					done=1
			End Select
			
		Case $803
			done=1
	End Select
	
Wend

FreeGadget window_about_label3
FreeGadget window_about_label2
FreeGadget window_about_label1
FreeGadget window_about_done
FreeGadget window_about

ActivateWindow window

End Function

Function create_window_commands()

window_commands = CreateWindow("Commands",277,219,449,157,window,3)
window_commands_done = CreateButton("Done",332,105,100,20,window_commands,0)
SetGadgetLayout window_commands_done,1,0,1,0
window_commands_label = CreateLabel("LoadTaskIcon(), TaskBarIcon(), FocusTaskBar(), TaskBarEvent(), ModifyTaskBar(), TaskBarMenuEvent(), AddIconMenu(), DeleteIconMenu()",5,5,429,91,window_commands,0)
SetGadgetLayout window_commands_label,0,0,0,0

While done=0 

	; 
	WaitEvent()

	; get the type of event.
	event_type=EventID()
	Select event_type

		;was it a gadget action event?
		Case $401
	
			; select the gadget that made the event.
			Select EventSource()
	
				Case window_commands_done
					done=1
			End Select
			
		Case $803
			done=1
	End Select
	
Wend

FreeGadget window_commands_done
FreeGadget window_commands_label
FreeGadget window_commands

ActivateWindow window

End Function

Guy Fawkes

(Posted 2009) [#2]

anyone?

jfk EO-11110

(Posted 2009) [#3]

To minimize the window you only need a userlib declaration. It might be possible to do this with SetWindowPlacement. In B3D hwnd is GetEnv$("AppHwnd") or something like that :). As the second parameter the function wants a pointer to a structure named "WINDOWPLACEMENT". You have to google and then create a bank with the same structure.

The declaration in the userlib file may be something like this:
SetWindowPlacement(hwnd,WINDOWPLACEMENT*)

Then, in Blitz you'd say SetWindowPlacement(int(GetEnv$("AppHwnd")), mybank)

In the bank "mybank" you should then be able to set certain veriables for minimizing, displaying etc.

Become familar with using USERLIBS in order to use Windows API functions, like minimizing a window or so! It's easy and powerful.

http://allapi.mentalis.org/agnet/apiguide.shtml
http://msdn.microsoft.com/en-us/library/aa383749%28VS.85%29.aspx

Your above code seems like a megaton of code, do you really expect people to read the who stuff? :) As I said, what you need is a single line of code.