Image not appearing on screen

Blitz3D Forums/Blitz3D Beginners Area/Image not appearing on screen

OwlEpicurus

(Posted 2009) [#1]

I decided to write a small program that could help me improve my knowledge of programming and Japanese at the same time. I've encountered a bit of a strange problem, though, and I have no idea what the error is.

Function MainMenu()
	
	back = LoadImage("Great_Wave_off_Kanagawa2.jpg")
	
	Dim optionBox(6,1)
	Dim optionX(6)
	Dim optionY(6)
	Dim optionName$(6)
	
	optionName$(0) = "Lesson: "+LessonName$
	optionName$(1) = "Start Lesson"
	optionName$(2) = "Change Lesson"
	optionName$(3) = "Switch User"
	optionName$(4) = "Options"
	optionName$(5) = "View Progress"
	optionName$(6) = "Exit"
	
	For i = 0 To 6
		optionBox(i,0) = CreateImage(StringWidth(optionName$(i))+8,StringHeight(optionName$(i))+8)
		SetBuffer ImageBuffer(optionBox(i,0))
		Color 222,218,184
		Rect 0,0,ImageWidth(optionBox(i,0)),ImageHeight(optionBox(i,0))
		Color 0,0,0
		Text 4,4,optionName$(i)
		
		optionBox(i,1) = CreateImage(StringWidth(optionName$(i))+8,StringHeight(optionName$(i))+8)
		SetBuffer ImageBuffer(optionBox(i,1))
		Color 109,160,150
		Rect 0,0,ImageWidth(optionBox(i,1)),ImageHeight(optionBox(i,1))
		Color 0,0,0
		Text 4,4,optionName$(i)
		
		optionX(i) = SCREENWIDTH/2-ImageWidth(optionBox(i,0))/2
		
		If i = 0
			optionY(i) = SCREENHEIGHT/2-ImageHeight(optionBox(i,0))
		ElseIf i = 1
			optionY(i) = optionY(i-1)+2*ImageHeight(optionBox(i-1,0))
		Else
			optionY(i) = optionY(i-1)+ImageHeight(optionBox(i-1,0))
		EndIf
		
	Next
	
	selection = 1
	
	Repeat
	
		Flip
		Cls
		
		SetBuffer BackBuffer()
		DrawImage back,0,0
		For i = 0 To 6
			If i = selection
				DrawImage optionBox(i,1),optionX(i),optionY(i)
			Else
				DrawImage optionBox(i,0),optionX(i),optionY(i)
			EndIf
		Next
		
		If KeyHit(DOWNKEY)
			selection = selection+1
			If selection > 6
				selection = 1
			EndIf
		EndIf
		
		If KeyHit(UPKEY)
			selection = selection-1
			If selection < 1
				selection = 6
			EndIf
		EndIf
		
		If KeyHit(ENTERKEY)
			con = 1
		EndIf
		
		If KeyHit(ESCKEY)
			End
		EndIf
	
	Until con = 1
	
	FreeImage back
	
	For i = 0 To 6
		FreeImage optionBox(i,0)
		FreeImage optionBox(i,1)
	Next
	
	Select selection
	
		Case 1
			DebugLog "'Start Lesson' Check"
			
		Case 2
			DisplayLessonIndex()
			
		Case 3
			DisplayUsers()
			
		Case 4
			DisplayOptions()
			
		Case 5
			DisplayProgress()
			
		Case 6
			End
	
	End Select
	
End Function

This is supposed to produce a main menu that offers the user 5 different options as well as displaying what the currently selected lesson is. For the most part, it does exactly that. However, the 'Exit' box disappears when highlighted. None of the others do, yet the same bit of code draws all of them. What is the cause of this?

puki	(Posted 2009) [#2]

I'd say move Flip and Cls to after the For/Next loop

_Skully

(Posted 2009) [#3]

reverse these... you are CLS'ing your last image

	Cls
	SetBuffer BackBuffer()

OwlEpicurus

(Posted 2009) [#4]

Puki:

That fixed the problem, but why did that only affect the last box and not the others?

puki	(Posted 2009) [#5]

Heh, that explains why my suggestion would work. I knew it was something like that when I saw the Flip at the start of the loop.

puki	(Posted 2009) [#6]

Your last box is exactly that - the last one before you free the image in your loop - you were killing it. The last box would always be affected.

OwlEpicurus

(Posted 2009) [#7]

Thanks.