Fire

Blitz3D Forums/Blitz3D Beginners Area/Fire

AJ00200

(Posted 2009) [#1]

I need an easy way to make fire.
Does anyone know how.

PS, don't say rub 2 sticks together, I want real suggestions

GfK	(Posted 2009) [#2]

~~Rub two sticks togeth~~... oh.... erm, particle systems. You need a particle system. Try Particle Candy.

AJ00200

(Posted 2009) [#3]

Wow, that looks like it will be it.
Is there any free ones?

PS - LOL

AJ00200

(Posted 2009) [#4]

Never mind,
Just got one out of the archives unless there's a free one you recommend.

josk	(Posted 2009) [#5]

This is worth a look
Click here

I would recommend particle candy if you can afford it.

AJ00200

(Posted 2009) [#6]

Yeah, that was the same one I found.
I don't really want to pay that much just to use fire, but thanks for your help.

With that other one, how would I make fire
(that code is way too big for me to look at)

josk	(Posted 2009) [#7]

Look in the includes folder and open test_particles, its not a big file.

You should be able to rip some code from there to get a fire going.

Aussie

(Posted 2009) [#8]

Gday.
Try this. http://www.blitzbasic.com/Community/posts.php?topic=80922#910970

Jerome Squalor

(Posted 2009) [#9]

why don't you just do it yourself? just make a quick particle system and work with it a bit until you get it look how you want it. I myself never bothered with buying a particle system thingy ma jiggy. I dont know, it seems to me that the extra bit of work is ok considering all the other times you will probably use something as common as fire. I guess its just opinion...

AJ00200

(Posted 2009) [#10]

I don't know much about particle systems, and I need to get it working soon, so I can't make my own.

_PJ_	(Posted 2009) [#11]

A 'particle system' at te very simplest is simoly code to manage the production, recycling and deletion of small visual effects (i.e. particles), especially when these effects move in a set pattern or within other boundaries, so, unless you have a specific need for many particle effects all to be managed under the same system, you might as well coe your own for a specific effect requirement.

Essentially, fire / flames wobble a bit and move upwards, fading / disappearing at a critical height. Generally speaking, (normal 'orangey') flames are white at their hottest to red at the cool points.

So your particles which may be "wisp-like" sprites would have a setup something like:

Type Particle
Field Spr=CopySprite(MasterFlameSprite)
Field Size
End type

And the functions to emit/ update might e like this: (Just a quick scribble here. It may have typos in etc.)

Function SpawnFire(X,Y,Z,Size)
local EmitterPivot=CreatePivot()
PositionEntity EmitterPivot,X,Y,Z
For f=1 to Size
Flame.Particle = New Particle
EntityParent Flame\Spr,EmitterPivot
Next
End Function
 
Function UpdateFire(EmitterPivot)
For IterFlame.Particle=Each Particle
If (IterFlame\Emitter=EmitterPivot)
TranslateEntity IterFlame\Spr,Rand(-1,1),2,Rand(-1,1),True
If (EntityY(IterFlame\Spr,False)>(IterFlame\Size)))
PositionEntity IterFlame\Spr,0,0,0,False
Moveentity Iterflame\Spr,Rand(Size)- Size  shr True),0,Rand(Size)- Size  shr True)
EntityColour IterFlame\Spr,160+EntityDistance(IterFlame\Spr,EmitterPivot)),160,32
Next
End Function

GIB3D

(Posted 2009) [#12]

3 Simple functions

CreateFire
UpdateFire
DeleteFire

What else could you possibly need?

Graphics3D 800,600,32,2
SetBuffer BackBuffer()
SeedRnd MilliSecs()

Global Light = CreateLight()


Global Camera = CreateCamera()
	PositionEntity Camera,0,3,-5
	RotateEntity Camera,30,0,0

CreateCylinder()

Local Sphere = CreateSphere(24)
	PositionEntity Sphere,0,-2,0
	ScaleEntity Sphere,4,1,4

While Not KeyDown(1)
	
	If KeyDown(57)
		CreateFire(0,0,0)
	EndIf
	
	UpdateFire()
	
	UpdateWorld
	RenderWorld
	
	Flip
	
Wend
End

Type Fire
	Field Entity,Light
	Field Life#
End Type

Function CreateFire.Fire(x#,y#,z#,life#=20)
	Local a.Fire = New Fire
	a\Entity = CreateSphere()
		PositionEntity a\Entity,x,y,z;Rotate if needed
		EntityColor a\Entity,255,128,0
		EntityAlpha a\Entity,.5
		
	a\Light = CreateLight(2,a\Entity)
		LightColor a\Light,255,128,0
	a\Life = life
	Return a
End Function

Function UpdateFire()
	Local a.Fire
	
	For a.Fire = Each Fire
		MoveEntity a\Entity,Rnd(-.1,.1),.1,Rnd(-.1,.1)
		
		a\Life = a\Life - 1
		If a\Life =< 0
			DeleteFire(a)
		EndIf
	Next
End Function

Function DeleteFire(a.Fire)
	FreeEntity a\Entity
	Delete a
End Function

_PJ_	(Posted 2009) [#13]

What else could you possibly need?

Some marshmallows? :D

GIB3D

(Posted 2009) [#14]

Hehe, now I'm obsessed with making it look better and better, here's this.

Edit: Changed it so now you can set your own speeds for rising and moving horizontally.

Graphics3D 800,600,32,2
SetBuffer BackBuffer()
SeedRnd MilliSecs()

Global Hertz = CreateTimer(75)

Global Light = CreateLight(2)
	PositionEntity Light,0,1,0
	LightRange Light,1
	
Global Pivot = CreatePivot()
Global Camera = CreateCamera(Pivot)
	PositionEntity Camera,0,7,-10
	RotateEntity Camera,40,0,0

Local Cylinder = CreateCylinder()
	EntityPickMode Cylinder,2

Local LimitPick = CreateSphere(4)
	EntityPickMode LimitPick,2
	FlipMesh LimitPick
	ScaleEntity LimitPick,50,50,50
	EntityColor LimitPick,0,0,0
	EntityShininess LimitPick,10
	
Local Sphere = CreateSphere(24)
	PositionEntity Sphere,0,-2,0
	ScaleEntity Sphere,4,1,4
	EntityPickMode Sphere,2

Local FPS[1],Time=MilliSecs()+1000

While Not KeyDown(1)
	WaitTimer(Hertz)
	
	If KeyDown(57)
		CreateFire(Rnd(-.1,.1),1,Rnd(-.1,.1),20,Rnd(.05,.2),Rnd(-.01,.01))
	EndIf
	
	If MouseDown(1)
		CameraPick Camera,MouseX(),MouseY()
		
		If PickedEntity() <> 0
			CreateFire(PickedX()+Rnd(-.1,.1),PickedY(),PickedZ()+Rnd(-.1,.1),20,Rnd(.05,.2),Rnd(-.01,.01))
		EndIf
	EndIf
	
	UpdateFire()
	
	TurnEntity Pivot,0,1,0
	
	UpdateWorld
	RenderWorld
	
	Locate 0,0
	Print "FPS " + FPS[0]
	Print "Left Mouse button or Spacebar to make fire"
	
	Flip
	Delay(5)
	
	FPS[1] = FPS[1] + 1
	
	If MilliSecs() => Time
		Time=MilliSecs()+1000
		FPS[0] = FPS[1]
		FPS[1] = 0
	EndIf
Wend
End

Type Fire
	Field Entity,Light
	Field Life#,LifeStart#
	Field Spread#
	Field RiseSpeed#
End Type

Function CreateFire.Fire(x#,y#,z#,life#=20,rise_speed#=.1,horizontal_spread#=0)
	Local a.Fire = New Fire
	Local LightRGB# = Rnd(255,128)
	
	a\Entity = CreateSphere()
		PositionEntity a\Entity,x,y,z;Rotate if needed
		EntityColor a\Entity,LightRGB,LightRGB/2,0
		EntityAlpha a\Entity,.5
		
	a\Light = CreateLight(2,a\Entity)
		LightColor a\Light,LightRGB,LightRGB/2,0
		
	a\Life = life
	a\LifeStart = a\Life
	
	a\Spread = horizontal_spread
	a\RiseSpeed = rise_speed
	
	Return a
End Function

Function UpdateFire()
	Local a.Fire
	
	For a.Fire = Each Fire
		Local LifeScale# = (a\Life/2)/a\LifeStart
		ScaleEntity a\Entity,LifeScale,LifeScale,LifeScale
		MoveEntity a\Entity,a\Spread,a\RiseSpeed,a\Spread
		
		LightRange a\Light,LifeScale*2
		
		a\Life = a\Life - 1
		If a\Life =< 0
			DeleteFire(a)
		EndIf
	Next
End Function

Function DeleteFire(a.Fire)
	FreeEntity a\Entity
	Delete a
End Function

Woowee this is kinda fun. Now I wanna make a customizable option for the size that it starts on, and what it will be when it finishes. Hmm I just have to figure out the math for that.

Edit: I guess I'm gonna have to take a little trip to GarrysMod to take a closer look at the Trails that you can add to props. You can choose their Start Size and their End Size, so here I go.

_PJ_	(Posted 2009) [#15]

And thus... a particle system is born...........

:)

GIB3D

(Posted 2009) [#16]

I'm glad you like it, it's extremely easy to make. I've also been TRYING to figure out 2D collision like blitz3d does with 3D collision after UpdateWorld but it's kinda hard. Mostly because I don't have enough information.

I figured it out, the code for going through starting and ending size over time is found in the UpdateFire() in the variable LifeScale

Graphics3D 800,600,32,2
SetBuffer BackBuffer()
SeedRnd MilliSecs()

Global Hertz = CreateTimer(75)

Global Light = CreateLight(2)
	PositionEntity Light,0,1,0
	LightRange Light,1
	
Global Pivot = CreatePivot()
Global Camera = CreateCamera(Pivot)
	PositionEntity Camera,0,7,-10
	RotateEntity Camera,40,0,0

Local Cylinder = CreateCylinder()
	EntityPickMode Cylinder,2

Local LimitPick = CreateSphere(4)
	EntityPickMode LimitPick,2
	FlipMesh LimitPick
	ScaleEntity LimitPick,50,50,50
	EntityColor LimitPick,0,0,0
	EntityShininess LimitPick,10
	
Local Sphere = CreateSphere(24)
	PositionEntity Sphere,0,-2,0
	ScaleEntity Sphere,4,1,4
	EntityPickMode Sphere,2

Local FPS[1],Time=MilliSecs()+1000

While Not KeyDown(1)
	WaitTimer(Hertz)
	
	If KeyDown(57)
		CreateFire(Rnd(-.2,.2),1,Rnd(-.2,.2),20,Rnd(.05,.2),Rnd(-.01,.01))
	EndIf
	
	If MouseDown(1)
		CameraPick Camera,MouseX(),MouseY()
		
		If PickedEntity() <> 0
			CreateFire(PickedX()+Rnd(-.2,.2),PickedY(),PickedZ()+Rnd(-.2,.2),20,Rnd(.05,.2),Rnd(-.01,.01),.5,1)
		EndIf
	EndIf
	
	UpdateFire()
	
	TurnEntity Pivot,0,1,0
	
	UpdateWorld
	RenderWorld
	
	Locate 0,0
	Print "FPS " + FPS[0]
	Print "Left Mouse button or Spacebar to make fire"
	
	Flip
	Delay(5)
	
	FPS[1] = FPS[1] + 1
	
	If MilliSecs() => Time
		Time=MilliSecs()+1000
		FPS[0] = FPS[1]
		FPS[1] = 0
	EndIf
Wend
End

Type Fire
	Field Entity,Light
	Field Life#,LifeStart#
	Field HorizontalSpeed#
	Field RiseSpeed#
	
	Field StartSize#
	Field EndSize#
End Type

;

Function CreateFire.Fire(x#,y#,z#,life#=20,rise_speed#=.1,horizontal_speed#=0,start_size#=.5,end_size#=0)
	Local a.Fire = New Fire
	Local LightRGB# = Rnd(255,128)
	
	a\Entity = CreateSphere()
		PositionEntity a\Entity,x,y,z;Rotate if needed
		EntityColor a\Entity,LightRGB,LightRGB/2,0
		EntityAlpha a\Entity,.5
		
	a\Light = CreateLight(2,a\Entity)
		LightColor a\Light,LightRGB,LightRGB/2,0
		
	a\Life = life
	a\LifeStart = a\Life
	
	a\HorizontalSpeed = horizontal_speed
	a\RiseSpeed = rise_speed
	
	a\StartSize = start_size
	a\EndSize = end_size
	
	Return a
End Function

Function UpdateFire()
	Local a.Fire
	
	For a.Fire = Each Fire
		Local LifeScale# = ((a\Life/a\LifeStart)*(a\EndSize-a\StartSize))-a\EndSize ; Calculates how big you want it to be and overtime changes to the endsize through multiplication and stuff hehe.
		
		ScaleEntity a\Entity,LifeScale,LifeScale,LifeScale
		MoveEntity a\Entity,a\HorizontalSpeed,a\RiseSpeed,a\HorizontalSpeed
		
		If LifeScale > 0
			LightRange a\Light,LifeScale*2
		EndIf
		
		a\Life = a\Life - 1
		If a\Life < 0
			DeleteFire(a)
		EndIf
	Next
End Function

Function DeleteFire(a.Fire)
	FreeEntity a\Entity
	Delete a
End Function

And now for those with Blitz3D+.dll I added a Light Range Limit.
Download Blitz3D+.dll here
http://www.blitzbasic.com/Community/posts.php?topic=75711

Graphics3D 800,600,32,2
SetBuffer BackBuffer()
SeedRnd MilliSecs()

Global Hertz = CreateTimer(75)

Global Light = CreateLight(2)
	PositionEntity Light,0,1,0
	LightRange Light,1
	
Global Pivot = CreatePivot()
Global Camera = CreateCamera(Pivot)
	PositionEntity Camera,0,7,-10
	RotateEntity Camera,40,0,0
	
	
Local Cylinder = CreateCylinder()
	EntityPickMode Cylinder,2

Local LimitPick = CreateSphere(4)
	EntityPickMode LimitPick,2
	FlipMesh LimitPick
	ScaleEntity LimitPick,50,50,50
	EntityColor LimitPick,0,0,0
	EntityShininess LimitPick,10
	
Local Sphere = CreateSphere(24)
	PositionEntity Sphere,0,-2,0
	ScaleEntity Sphere,4,1,4
	EntityPickMode Sphere,2

Local FPS[1],Time=MilliSecs()+1000

While Not KeyDown(1)
	WaitTimer(Hertz)
	
	
	If KeyDown(57)
		CreateFire(Rnd(-.2,.2),1,Rnd(-.2,.2),20,Rnd(.05,.2),Rnd(-.01,.01))
	EndIf
	
	If MouseDown(1)
		CameraPick Camera,MouseX(),MouseY()
		
		If PickedEntity() <> 0
			CreateFire(PickedX()+Rnd(-.2,.2),PickedY(),PickedZ()+Rnd(-.2,.2),20,Rnd(.05,.2),Rnd(-.01,.01),.5,1)
		EndIf
	EndIf
	
	UpdateFire()
	
	TurnEntity Pivot,0,1,0
	
	UpdateWorld
	RenderWorld
	
	Locate 0,0
	Print "FPS " + FPS[0]
	Print "Left Mouse button or Spacebar to make fire"
	
	Flip
	Delay(5)
	
	FPS[1] = FPS[1] + 1
	
	If MilliSecs() => Time
		Time=MilliSecs()+1000
		FPS[0] = FPS[1]
		FPS[1] = 0
	EndIf
Wend
End

Type Fire
	Field Entity,Light
	Field Life#,LifeStart#
	Field HorizontalSpeed#
	Field RiseSpeed#
	
	Field StartSize#
	Field EndSize#
End Type

;

Function CreateFire.Fire(x#,y#,z#,life#=20,rise_speed#=.1,horizontal_speed#=0,start_size#=.5,end_size#=0)
	Local a.Fire = New Fire
	Local LightRGB# = Rnd(255,128)
	
	a\Entity = CreateSphere()
		PositionEntity a\Entity,x,y,z;Rotate if needed
		EntityColor a\Entity,LightRGB,LightRGB/2,0
		EntityAlpha a\Entity,.5
		
	a\Light = CreateLight(2,a\Entity)
		LightColor a\Light,LightRGB,LightRGB/2,0
		BP_SetLightMaxRange(a\Light,life*.25)
		
	a\Life = life
	a\LifeStart = a\Life
	
	a\HorizontalSpeed = horizontal_speed
	a\RiseSpeed = rise_speed
	
	a\StartSize = start_size
	a\EndSize = end_size
	
	Return a
End Function

Function UpdateFire()
	Local a.Fire
	
	For a.Fire = Each Fire
		Local LifeScale# = ((a\Life/a\LifeStart)*(a\EndSize-a\StartSize))-a\EndSize ; Calculates how big you want it to be and overtime changes to the endsize through multiplication and stuff hehe.
		
		ScaleEntity a\Entity,LifeScale,LifeScale,LifeScale
		MoveEntity a\Entity,a\HorizontalSpeed,a\RiseSpeed,a\HorizontalSpeed
		
		If LifeScale > 0
			LightRange a\Light,LifeScale
			BP_SetLightMaxRange(a\Light,LifeScale*.25)
		EndIf
		
		a\Life = a\Life - 1
		If a\Life < 0
			DeleteFire(a)
		EndIf
	Next
End Function

Function DeleteFire(a.Fire)
	FreeEntity a\Entity
	Delete a
End Function

AJ00200

(Posted 2009) [#17]

Thanks everyone.
Ill see what I can do.
If mine turns out good, Ill put it in the code arcs, and on my website.

If all else fails, I'll use someone else's.

Thanks again,
AJ00200