3 Different Sprites on Screen using Type?

Blitz3D Forums/Blitz3D Beginners Area/3 Different Sprites on Screen using Type?

Hotshot2005

(Posted 2009) [#1]

I am trying to create 3 Different Enemys on screen at the same time by using Type but I am suck at it for some reason.

Pongo

(Posted 2009) [#2]

here is a simple example. I'll expand on this in a bit and add more comments. It would also help if your question was a bit more specific,... types can be a large topic.

I've also used types within types in this example to show how that can be done.

Global screenX = 640
Global screenY = 480

Graphics screenX,screenY,0,2
SetBuffer BackBuffer()
SeedRnd  MilliSecs()

Type vector2
	Field x#
	Field y#
End Type

Type rgbcolor
	Field r
	Field g
	Field b
End Type

Type enemy
	Field pos.vector2
	Field vel.vector2
	Field Col.rgbcolor
End Type

Type player
	Field pos.vector2
	Field vel.vector2
End Type

enemycount = 10 ; how many enemies?

For loop = 1 To enemycount
	e.enemy = New enemy
	
	;assign a random starting position to the sprite
	e\pos = New vector2
	e\pos\x = Rnd(screenX)
	e\pos\y = Rnd(screenY)
	
	e\vel = New vector2 ;assign a random velocity to the enemy
	e\vel\x = Rnd(-1.0,1.0)
	e\vel\y = Rnd(-1.0,1.0)	
	
	;make each enemy a unique color
	e\col = New rgbcolor
	e\col\r = Rnd(256)
	e\col\g = Rnd(256)
	e\col\b = Rnd(256)
Next ;done creating enemies

p.player = New player ; create a player
p\pos = New vector2

While Not KeyHit(1) ;main loop. Repeat until esc is hit
	
	;set player to mouse coordinates
	p\pos\x = MouseX()
	p\pos\y = MouseY()
	
	;loop through the enemies To draw them To the screen
	For e.enemy = Each enemy
		Color e\col\r,e\col\g,e\col\b	;set the color to that of this enemy
		e\pos\x = e\pos\x + e\vel\x
		e\pos\y = e\pos\y + e\vel\y
		
		;check to see if enemy has hit edge of screen. If it has hit, reverse direction
		If e\pos\x > screenX : e\pos\x = screenX : e\vel\x = - e\vel\x : EndIf
		If e\pos\x < 0 : e\pos\x = 0: e\vel\x = - e\vel\x : EndIf
		If e\pos\y >screenY :e\pos\y = screenY:	e\vel\y = - e\vel\y:	EndIf
		If e\pos\y <0:e\pos\y = 0:e\vel\y = -e\vel\y:	EndIf
		
		If RectsOverlap(e\pos\x-5,e\pos\y-5,10,10,p\pos\x-10,p\pos\y-10,20,20) ;quick rectangle check to see if enemy has hit player
			Text 50,50,"Player has been hit!"
		EndIf
		
		Oval e\pos\x-5,e\pos\y-5,10,10 ;draw a circle for this enemy
	Next
	
	;draw the player to the screen
	Color 255,255,255
	Oval p\pos\x-10,p\pos\y-10,20,20 ;draw a circle for this enemy
	
	Flip
	Cls
Wend ;end main loop

End ;end program

A few notes:
This has been written for easy reading, not efficiency. For example, if you bump up the enemy count, things will slow down quickly. This is because of the slow Oval command I am using to draw them. Changing them to a regular bitmap will speed things up tremendously.

_PJ_	(Posted 2009) [#3]

How about you post something of your code, Hotshot, so we can see where the problems are?

WERDNA

(Posted 2009) [#4]

Here is my favoriote way to set up enemy types.
I just create ONE type, called Enemy, and using its Typ field, I can
make it act in different ways.

 Graphics 800,600,0,1
SetBuffer BackBuffer()
AutoMidHandle True 

Type Enemy;This is the main enemy type
Field x,y,typ;He has 3 fields. X, Y, And typ, which is used to tell what Kind of enemy he is.
End Type 


MakeEnemy(1);Everytime this function is called, 1 enemy is created.
MakeEnemy(2);The number between the parantheses, is what Kind of enemy he will be.
MakeEnemy(3)


While Not KeyDown(1); < Main loop
Cls;Clear the screen

UpDateEnemys();Update the enemies movement, and draw them

Flip;Flip the back buffer with the front buffer.
Wend ;End of main loop


Function MakeEnemy(Typ);This is the enemy creation function. 
E.Enemy = New Enemy;Make 1 new enemy
E\x = 400;set its X coordinates to 400
E\y = 300;set Y coordinates to 300
E\typ = Typ;set its type to Typ(The value you put in when you first called the function.)
End Function 


Function UpDateEnemys();The update enemies function.
For E.Enemy = Each Enemy;Begin a For Loop checking each enemy.

E\x = E\x + Rand(-1,1);Move the enemy a little bit.
E\y = E\y + Rand(-1,1);

If E\typ = 1;If this is a Type1 enemy, then color him Red.
Color 255,0,0
Plot E\x,E\y
End If 

If E\typ = 2;If its a Type2 enemy instead, then color him Green.
Color 0,255,0
Plot E\x,E\y
End If

If E\typ = 3;And finally if its a Type3 enemy, color him Blue.
Color 0,0,255
Plot E\x,E\y
End If 

Next ;End of For Loop
End Function

This is basically an easy way to make a single Type, act like several.
Instead of creating a seperate Type for each and every enemy, which
can get annoying especially if each and every one of them has its own
seperate For Loop, I simply create ONE Type, and ONE For Loop to
control them all, and depending on their Typ Value, They will act
differently.
In the section where it checks their Typ value and then colors them
accordingly, you could put in code to make them move differently
depending on their typ, to make them attack differently, basically
whatever you wanted.

Hope this helps you out,

WERDNA

Hotshot2005

(Posted 2009) [#5]

it is interesting to learn from type from pongo and Werdna.

If I going to used 3 different enemys sprites or images, would be better if I did this than using dim arrays?

Type Enemys
     field images[3] ; 3 different enemys images or sprites]
     field X,Y
     field Health
     field Hit
end type

how i used images arrays when using types to show 3 different enemys on the screen?

_PJ_	(Posted 2009) [#6]

The whole purpose of using Custom Types is that you can create many instances of the same type, so if I am understanding what you want correctly, then you shouldn't need any form of array.

Just create a new instance for each enemy:

Type Enemies
Field Image
Field X,Y
Field Health
Field Hit

Enemy_1.Enemies = New Enemies
Enemy_1\Image=LoadImage("Enemy1.bmp")

Enemy_2.Enemies = New Enemies
Enemy_2\Image=LoadImage("Enemy2.bmp")

Enemy_3.Enemies = New Enemies
Enemy_3\Image=LoadImage("Enemy3.bmp")

Hotshot2005

(Posted 2009) [#7]

ahhh right....that is much better than I thought.

what happen if I have images of punch and kick for each enemys?

would I do this

Type Enemies
     field images
     field X,Y
     field Walk  ???
     field Punch
     field Kick
     field Health
     field hit
end type

Enemy_1.Enemies = New Enemies
; For enemies standing still
Enemy_1\Image=LoadImage("Enemy1.bmp")
; for enemies to walk
Enemy_1\Image\walk=LoadImage("Enemy1.bmp")
; for enemies punch
Enemy_1\Image\punch=LoadImage("Enemy1.bmp")
; for enemies kick
Enemy_1\Image\kick=LoadImage("Enemy1.bmp")

Do you think it would be better if i did that above?

_PJ_	(Posted 2009) [#8]

Well, if the images are separate and not frames of animation, then yes, you were nearly there. Remember the filename must be accurate to the right image file.
You can assign the handle of the images to any field of your type.

Type Enemies
     field images
     field X,Y
     field Walk  ???
     field Punch
     field Kick
     field Health
     field hit
end type

Enemy_1.Enemies = New Enemies
; For enemies standing still
Enemy_1\Image=LoadImage("Enemy1.bmp")
; for enemies to walk
Enemy_1\walk=LoadImage("Enemy1walk.bmp")
; for enemies punch
Enemy_1\punch=LoadImage("Enemy1punch.bmp")
; for enemies kick
Enemy_1\kick=LoadImage("Enemy1kick.bmp")

Have a good read up of Custom Types and try out the examples to get a feel of how they work.
http://www.blitzbasic.com/b3ddocs/command.php?name=Type&ref=2d_a-z

Hotshot2005

(Posted 2009) [#9]

thank you very much malice and everyone too :)