2.5d shooter (like rtype delta)

Blitz3D Forums/Blitz3D Beginners Area/2.5d shooter (like rtype delta)

Pete Carter

(Posted 2006) [#1]

hi ive just started make a small side project with a friend whos made on shoot em ups so i said to him why dont we make one sounds easy. ive run into two things ive never encountered before.

1. what's the best way of having a startfield moving as a back ground behind my models ive tried a cube and a sphere both don't look right because of the stars not appearing to move straight because of the perspective?

2. im using camera zoom to get rid of the fisheye effect of the camera but is there a better way?

Pete

Jams	(Posted 2006) [#2]

You could try an orthographic projection ( CameraProjMode() )

Pete Carter

(Posted 2006) [#3]

orthographic projection was ok but looked a bit odd, thanks anyway.

ive just been working on it and im happy with the camera zoom now its just the starfield i need help with now?

Pete

Jams	(Posted 2006) [#4]

"ive tried a cube and a sphere both don't look right"

Could you be a bit more specific on what you tried? did you scroll the texture or were you rotating those shapes? or something else?

Pete Carter

(Posted 2006) [#5]

sorry ive flipped two cubes and had them rotating at different speeds and the same with spheres. im not sure how to scroll textures if you could show me how that would be great :O)

Jams	(Posted 2006) [#6]

I made some code for you to study :)

Specially the command PositionTexture()

;Starfield example for pete carter

Graphics3D( 800, 600 )
SetBuffer( BackBuffer() )
SeedRnd( MilliSecs() )

Local Cam% = CreateCamera()

;4 different starfield textures (you may want to loadimage instead).
Local StarfieldTexture1% = CreateStarfield( 200 )
Local StarfieldTexture2% = CreateStarfield( 150 )
Local StarfieldTexture3% = CreateStarfield( 100 )
Local StarfieldTexture4% = CreateStarfield( 50 )

;4 layers of stars.
Local Layer1% = CreateSprite( Cam% )
				PositionEntity( Layer1%, 0, 0, 1.5 ) ;In front of camera.
				EntityBlend( Layer1%, 3 ) ;additive blending.
				EntityTexture( Layer1%, StarfieldTexture1% )

Local Layer2% = CreateSprite( Cam% )
				PositionEntity( Layer2%, 0, 0, 1.5 )
				EntityBlend( Layer2%, 3 )
				EntityTexture( Layer2%, StarfieldTexture2% )

Local Layer3% = CreateSprite( Cam% )
				PositionEntity( Layer3%, 0, 0, 1.5 )
				EntityBlend( Layer3%, 3 )
				EntityTexture( Layer3%, StarfieldTexture3% )

Local Layer4% = CreateSprite( Cam% )
				PositionEntity( Layer4%, 0, 0, 1.5 )
				EntityBlend( Layer4%, 3 )
				EntityTexture( Layer4%, StarfieldTexture4% )


;Textures offset variabe.
Local Offset# = 0

Repeat

		;Decrement the offset.
		Offset# = Offset# - .001
		;Scroll the starfield textures..
		PositionTexture( StarfieldTexture1%, Offset#, 0 )
		PositionTexture( StarfieldTexture2%, Offset# *.7, 0 )
		PositionTexture( StarfieldTexture3%, Offset# *.4, 0 )
		PositionTexture( StarfieldTexture4%, Offset# *.1, 0 )

UpdateWorld(): RenderWorld(): Flip()
Until KeyHit( 1 )



;Function to make a star texture.
Function CreateStarfield%( Brightness% )
			Local Image% = CreateImage( 256, 256 )
			Local Texture% = CreateTexture( 256, 256, 256 )
			Local i%

			SetBuffer( ImageBuffer( Image% ) )

			For i% = 0 To 250
				Bright% = Rand( Brightness% -50, Brightness% +50 )
				Color( Bright%, Bright%, Bright% )
				Plot( Rand( 256 ), Rand( 256 ) )
			Next

			CopyRect( 0, 0, 512, 512, 0, 0, ImageBuffer( Image% ), TextureBuffer( Texture% ) )

			SetBuffer BackBuffer()
			Return Texture%
End Function

Baystep Productions

(Posted 2006) [#7]

yeah, sprites are the easiest way of doing this. Will consume the least amount of tris, and is the quickest.

Pete Carter

(Posted 2006) [#8]

thanks jams i will test out your code. looks like it will do the trick. thanks again!

Pete

Pete Carter

(Posted 2006) [#9]

Jams just ran your code thats spot on! thanks for your help.

Pete

Pete Carter

(Posted 2006) [#10]

one quick question should i scale it up so that when i have the sprite at the back of my scene it still fills the whole screen. or can i position it near the camera and somehow change the z order so that my models get rendered over the top of the stars?

hope you get what im trying to say?

Pete

Jams	(Posted 2006) [#11]

You can do either, putting it close to the camera and setting it's entity order [ EntityOrder() ] will render it before everything else in your game (everything else drawn on top)..

Also worth mentioning, you might like to scale your sprites in a 1.33:1 aspect ratio to match the screen [ ie ScaleSprite( HND%, 1.33, 1 ) ]

Happy to help :)

b32	(Posted 2006) [#12]

To avoid the fisheye, camerazoom should be around 2.4.
http://www.blitzbasic.com/Community/posts.php?topic=20921

Pete Carter

(Posted 2006) [#13]

thanks im really getting somewhere with my shooter now. im now adding stuff to make it look better, stars was the first thing then ill add particle effects.

Pete