collision mav

Blitz3D Forums/Blitz3D Beginners Area/collision mav

Polarix

(Posted 2017) [#1]

Hey guys, so every time i press run this gets a MAV unless i take collisions out. This doesn't make sense everything else is good

 Graphics3D 1366,768,0,1
SetBuffer BackBuffer()
SeedRnd MilliSecs()

Const collider_col = 1
Const map_col = 2

AntiAlias = True 

HidePointer()

Global light = CreateLight()
Global plr = CreateCamera()
	CameraRange plr,0.001,10000
	CameraFogRange plr,0,100

Global room1 = LoadMesh("GFX\room.b3d")
EntityType room1,map_col,2

Global viewport_center_x = GraphicsWidth () / 2
Global viewport_center_y = GraphicsHeight () / 2

Global mouse_x_speed_1#, mouse_x_speed_2#,mouse_x_speed_3#,mouse_x_speed_4#,mouse_x_speed_5#
Global mouse_y_speed_1#,mouse_y_speed_2#,mouse_y_speed_3#,mouse_y_speed_4#,mouse_y_speed_5#

Global mouselook_x_inc# = 0.3 
Global mouselook_y_inc# = 0.3 
Global mouse_left_limit = 250 
Global mouse_top_limit = 250 
Global mouse_bottom_limit = GraphicsHeight () - 250 

Global user_plr_pitch#
Global up#, side#

Global collider = CreatePivot()
EntityType collider,collider_col,1
PositionEntity collider,5.5,5,-0.5
EntityRadius collider, 0.4

Collisions collider_col,room1,3,1

While Not KeyHit(1)
	mouselook()
	
	If KeyDown(31) Then MoveEntity collider,0,0,-.1
	If KeyDown(17) Then MoveEntity collider,0,0,.1
	If KeyDown(30) Then MoveEntity collider,-.1,0,0
	If KeyDown(32) Then MoveEntity collider,.1,0,0
	

	UpdateWorld
	RenderWorld
	Flip 
Wend
End







Function CurveValue#(number#, oldn#, smooth#)
    Return oldn + (number - oldn) * (1.0 / smooth)
End Function

Function MouseLook()

	PositionEntity plr, EntityX(collider), EntityY(collider)+1, EntityZ(collider)
	MoveEntity plr, side, up, 0

	mouse_x_speed_5# = mouse_x_speed_4#
	mouse_x_speed_4# = mouse_x_speed_3#
	mouse_x_speed_3# = mouse_x_speed_2#
	mouse_x_speed_2# = mouse_x_speed_1#
	mouse_x_speed_1# = MouseXSpeed ( )
	mouse_y_speed_5# = mouse_y_speed_4#
	mouse_y_speed_4# = mouse_y_speed_3#
	mouse_y_speed_3# = mouse_y_speed_2#
	mouse_y_speed_2# = mouse_y_speed_1#
	
	If InvertMouse Then
		mouse_y_speed_1# = -MouseYSpeed ( )	
	Else
		mouse_y_speed_1# = MouseYSpeed ( )	
	EndIf
	
	
	the_yaw# = ( ( mouse_x_speed_1# + mouse_x_speed_2# + mouse_x_speed_3# + mouse_x_speed_4# + mouse_x_speed_5# ) / 5.0 ) * mouselook_x_inc#
	the_pitch# = ( ( mouse_y_speed_1# + mouse_y_speed_2# + mouse_y_speed_3# + mouse_y_speed_4# + mouse_y_speed_5# ) / 5.0 ) * mouselook_y_inc#
	;^^^^^^

	TurnEntity collider, 0.0, -the_yaw#, 0.0 
	user_plr_pitch# = user_plr_pitch# + the_pitch#
	If user_plr_pitch# > 70.0 Then user_plr_pitch# = 70.0
	If user_plr_pitch# < -70.0 Then user_plr_pitch# = -70.0
	;^^^^^^
	RotateEntity plr, user_plr_pitch, EntityYaw(collider),0 
	If ( MouseX() > mouse_right_limit ) Or ( MouseX() < mouse_left_limit ) Or ( MouseY() > mouse_bottom_limit ) Or ( MouseY() < mouse_top_limit )
		MoveMouse viewport_center_x, viewport_center_y
	EndIf

End Function

Floyd

(Posted 2017) [#2]

It's likely that LoadMesh("GFX\room.b3d") failed for some reason.

When run from the IDE the current directory is set to a \tmp folder.
Try using the full path to room.b3d rather than the relative path GFX\.

Memory Access Violation is a catch-all "something went wrong" message.
If you enable Debug mode, at the bottom of the Program menu, you will usually get more useful information.

RemiD

(Posted 2017) [#3]

if one of your surface has more than 32000vertices or 32000 triangles, this will produce a MAV (on some computers)

in any case it is always better to use low details collidables (obstacles)

RemiD

(Posted 2017) [#4]

@LikeToMakeGames>>after a quick reading, i see these potential errors :

EntityType room1,map_col,2 ;should be EntityType room1,map_col

EntityType collider,collider_col,1 ; should be EntityType collider,collider_col

Collisions collider_col,room1,3,1 ;should be Collisions collider_col,map_col,2,1 ;ellipsoid to mesh, response stop

additionally, i suggest to set the collisions (entitytype, collisions) after you have positionned all your entities in the world, to prevent them of being stuck somewhere (because of collisions)

here is a similar scene with collisions ellipsoid->mesh (room) :

Graphics3D 800,600,32,2

HidePointer()

SeedRnd MilliSecs()

Const ellipsoid_col = 1
Const map_col = 2

Global camera = CreateCamera()
CameraRange camera,0.15,150
CameraClsColor(camera,000,000,000)

Global room1 = CreateCube()
FlipMesh(room1)
ScaleMesh(room1,10.0/2,3.0/2,10.0/2)
PositionMesh(room1,10.0/2,3.0/2,10.0/2)

;you only need a pivot with a radius to have an ellipsoid collider, but here i have added a sphere mesh just to see how the ellipsoid behaves
;Global ellipsoid = CreatePivot()
Global ellipsoid = CreateSphere(16)
ScaleMesh(ellipsoid,0.5/2,0.5/2,0.5/2)
EntityAlpha(ellipsoid,0.5)
EntityRadius ellipsoid, 0.25
PositionEntity(ellipsoid,5.0,0+0.25+0.01,5.0)

Global olight = CreateLight(2)
LightRange(olight,3.0)
LightColor(olight,255,255,255)
PositionEntity(olight,5,1.5,5)

EntityType room1,map_col
EntityType ellipsoid,ellipsoid_col
Collisions ellipsoid_col,map_col,2,1

While Not KeyHit(1)
	
	;turn left right
	If KeyDown(30) Then TurnEntity ellipsoid,0,3,0
	If KeyDown(32) Then TurnEntity ellipsoid,0,-3,0
	;move forward backward
	If KeyDown(17) Then MoveEntity ellipsoid,0,0,0.1
	If KeyDown(31) Then MoveEntity ellipsoid,0,0,-0.1
	;move down up
	If KeyDown(16) Then MoveEntity ellipsoid,0,-0.1,0
	If KeyDown(18) Then MoveEntity ellipsoid,0,0.1,0
	;camera view
	PositionEntity(camera,EntityX(ellipsoid,True),EntityY(ellipsoid,True),EntityZ(ellipsoid,True))
	RotateEntity(camera,EntityPitch(ellipsoid,True),EntityYaw(ellipsoid,True),EntityRoll(ellipsoid,True))
	TurnEntity(camera,45,0,0)
	MoveEntity(camera,0,0,-5)

	UpdateWorld()
	
	SetBuffer(BackBuffer())
	RenderWorld()
	
	Flip() 
	
Wend

End()

Zethrax

(Posted 2017) [#5]

If you're getting a MAV then you're either running the compiler in release mode or whatever you're loading is corrupt and the internal loading function can't handle it as a result.

You should run test builds in debug mode so that you get useful feedback from the debugger.

Most of the loader functions such as LoadMesh will return a zero if the resource you're trying to load doesn't load for some reason. You should check for a zero result and quit with an error message if the resource doesn't load (for release versions you may need more elegant ways of handling non-essential resources that won't load).

eg.
Global room1 = LoadMesh("GFX\room.b3d")
If room1 = 0 Then RuntimeError "ERROR: Failed to load 'GFX\room.b3d'."

If you upload the 'room.b3d' file along with any other required media and post a link then we can give you more useful info on the problem.

Polarix

(Posted 2017) [#6]

This happens still even if i use a cube entity

RemiD

(Posted 2017) [#7]

the code example i posted (in post #4) works well here without any MAV... Maybe a problem with your mesh ? (more than 32000vertices or/and more than 32000triangles in a surface ?)

Matty

(Posted 2017) [#8]

Put on debug mode and find out what the error message is... a mav by itself is rather meaningless....debug mode will show the exact location of the error (unless it is what RemiD says at which case it will MAV on renderworld)

Polarix

(Posted 2017) [#9]

Thanks guys I figured it out by the way

I put it like

 Collisions collider_col,room1,2,2

when it should have been

 Collisions collider_col,map_col,2,2