Play sound on collision problem?

Blitz3D Forums/Blitz3D Beginners Area/Play sound on collision problem?

NRJ	(Posted 2016) [#1]

I am new to Blitz3D, I am trying to play a sound when the player collides with the door, using the entitycollided command the sound gets played but it is not clear, it looks like it is played again and again instead of playing just once, I am unable to solve this problem , anybody please help me out of this.

Bobysait

(Posted 2016) [#2]

Use "ChannelPlaying(Sound)" to check if the sound is playing.
If not, play the sound

ps : Welcome there !

Dan	(Posted 2016) [#3]

just earlier today i was trying to find some code for sound, for my project (before i write something for it).

this is what i found:

codearchive

and the post from topknot here is the origin of the above's link , i think.

Bobysait

(Posted 2016) [#4]

If you want some stuff to use sounds, here is a little demo which manage to use multiple channels to play sounds.

I set it up to 4 channels arbitrary, but most hardware nowadays can maintain more than 30-50 channels at the same time.
It's just a sample test (old hardware are more restrictive, all depends on the target machine).

(I loaded a sound from windows but it may not exists on some version of windows... change the file for your needs)

Type TStaticChannel
	Field channel%
End Type

Function CreateStaticChannel.TStaticChannel()
	Local c.TStaticChannel = New TStaticChannel
	c\channel = 0
	Return c
End Function

Type TSound
	Field sound%
	Field channelHandler.TStaticChannel
	Field is3D%
End Type

Function CreateSound.TSound(file$, sound3D%=True)
	Local snd.TSound = New TSound
	If sound3D
		snd\sound = Load3DSound(file)
	Else
		snd\sound = LoadSound(file)
	EndIf
	snd\channelHandler = Null
	snd\is3D = sound3D
	Return snd
End Function

Function TSoundPlay(snd.TSound, entity%=0)
	
	; if a channel is already assigned to this sound, check if it is in use or not
	If snd\channelHandler<>Null
		
		; channel plays. The sound is already running.
		If ChannelPlaying(snd\channelHandler\channel) Then Return;
		
		; channel not playing : unassign it.
		snd\channelHandler\channel = 0
		snd\channelHandler = Null
		
	EndIf
	
	; so ... here, no channel are assigned to this sound
	; search an empty channel
	Local c.TStaticChannel
	For c = Each TStaticChannel
		
		; check if the channel already exists and if so, check if it is still playing
		If c\channel<>0
			If Not(ChannelPlaying(c\channel)) Then c\channel = 0
		EndIf
		
		; channel empty -> play the sound and get the channel created
		If c\channel=0
			; the sound will use this channel for the moment.
			snd\channelHandler = c
			; emit the sound (2D or 3D)
			If ((snd\is3D<>0) And (entity<>0))
				c\channel = EmitSound(snd\sound, entity)
			Else
				c\channel = PlaySound(snd\sound)
			EndIf
			
			Return
		EndIf
		
	Next
	
End Function


Const COLLISION_TYPE_PLAYER% = 1
Const COLLISION_TYPE_DOOR% = 2

Graphics3D 800,600,0,2
SetBuffer BackBuffer()

AmbientLight 0,0,0

Collisions COLLISION_TYPE_PLAYER, COLLISION_TYPE_DOOR, 2, 3


Local light1=	CreateLight		( 2 )
				PositionEntity	( light1, 50,50,-20 )
				LightRange		( light1, 80 )
				LightColor		( light1, 250,100,020 )
Local light2=	CreateLight		( 2 )
				PositionEntity	( light2, -50,40,-40 )
				LightRange		( light2, 80 )
				LightColor		( light2, 100,100,250 )
Local light3=	CreateLight		( 2 )
				PositionEntity	( light3, 0,-70,20 )
				LightRange		( light3, 60 )
				LightColor		( light3, 100,250,020 )
				
Local camera =	CreateCamera	( )
				PositionEntity	( camera, 10,10,-5 )
				TurnEntity		( camera, 45,45,0 )
				CreateListener	( camera, 0.5, 2, 0.5 )
				
Local player =	CreateSphere	( 16 )
				ScaleEntity		( player, .5,.9,.3 )
				EntityType		( player, COLLISION_TYPE_PLAYER )
				PositionEntity	( player, 3,1,2 )
				ResetEntity		( player )
				
Local plane	=	CreatePlane		( 8 )

Local door	=	CreateCube		( )
				FitMesh			( door, 0, 0, 0, 1,2,.1 )
				HideEntity		( door )
				EntityType		( door, COLLISION_TYPE_DOOR )
				
; create some doors
For d = 1 To 20
	Local copy=	CopyEntity		( door )
				PositionEntity	( copy, Rand(-30,10),0,Rand(0,15) )
				ResetEntity		( copy )
Next


; create some free channel (let's say 4 channel max at the same time)
For static_channel = 1 To 4
	CreateStaticChannel()
Next

; Load a 3D sound
Local MySound.TSound = CreateSound("C:\Windows\Media\ding.wav", True)


Repeat
	
	; do the 3D stuff/updates/etc...
	
	MoveEntity player, 0,0,Float(KeyDown(200)-KeyDown(208))*0.1
	TurnEntity player, 0, Float(KeyDown(205)-KeyDown(203))*5, 0
	
	; update world collisions
	UpdateWorld()
		
		If EntityCollided(player, COLLISION_TYPE_DOOR)
			
			; just call the function to play the sound, it will do the job.
			TSoundPlay ( MySound, player)
			
		EndIf
		
	; render the 3D
	RenderWorld()
		
		; 2D here
		Text 10,10, "some text ..."
		
	Flip True
	
Until KeyDown(1)

End

ps : I have an old sound library, I thought I posted it long times ago ... seems I didn't :)

RemiD

(Posted 2016) [#5]

I remember a problem that i have noticed in the past was that if there were 2 entities which emitted the same sound (which used the same channel) at the same time, only one entity emitted the sound. How to avoid that ? Maybe use one channel per entity (=different channel reference) ? Or load one sound per entity (=different sound reference) ?

NRJ	(Posted 2016) [#6]

Still I am unable to solve this problem. I am just trying to play a sound like door locked when the player collides with the door(like in Clive barker, max Payne ) only single time but the sound is playing several times . The code I am using is below.

Graphics3d 800*600

Type_player=1
Type_door=2
--------------
--------------
Player=createcamera( )
--------------
--------------

EntityType player,type_player
Door=createcube( )
--------------
--------------
EntityType door,type_door

Collisions type_player,type_door,2,2
snd=loadsound("e:\sounds\door_locked.wav")

While not keyhit(1)

If entitycollided(player,type_door) then
Playsound snd

updateworld
Renderworld

Flip
Wend
End

Bobysait

(Posted 2016) [#7]

well ...
I already answered your problem, everything is writen above.

assign a channel variable (init with 0) test if it exists and if so, if it's playing ...

local channel = 0

while not Keyhit(1)

[...]

if entitycollided(...)
    if channel=0 ; channel never used -> use it
        channel = playsound(snd)
    else ; channel exists -> check if it's playing.
        if not(channelplaying(channel)) then channel = playsound(snd)
    endif
endif

[...]
Wend

And that's all.

ps : you can use the [ code ] or [ codebox ] (without spaces) to surround your code.

skidracer

(Posted 2016) [#8]

A simpler solution would be to add a new entity type

Type_door_closed =2
Type_door_open =3

Start cube as say door_closed and on collision set the entity type of the cube to door_open.

This solves the underlying problem that you only want a single collision event with a closed door.

NRJ	(Posted 2016) [#9]

@BOBYSAIT
Thank you Bobysait for your help, your code has totally solved my problem, thanks for your consistent support.