Bmp for Particle

Blitz3D Forums/Blitz3D Beginners Area/Bmp for Particle

Hardcoal

(Posted 2015) [#1]

Hi..
When I see Particle engines they use bmp
Format and not png.. As a particle
But how can you turn bmp into transparent..?
Or do they just put it on a sprite?

Does it matter which format I'll be using?

Matty

(Posted 2015) [#2]

Some do use png.

If they are using bitmaps they may be simply be using additive blending in which case alpha doesnt always matter.

Alternatively they use a mask colour and set the mask to transparent.

Or they use two bitmaps. One with color info and the other usually greyscale as a transparency map.

Those are some possibilities.

RemiD

(Posted 2015) [#3]

When you load a texture, you can specify if you want to hide the black (0,0,0) texels (flag 4) or display a progressive transparency/opacity of some texels (flag 2), if the image has no alpha info, i suppose that the texels which are darker are the most transparent and the texels which are brighter are the most opaque.

You can also write the alpha of each texel after having loaded the image with flag 2.

From what i understand, png have rgba infos whereas bmp have only rgb infos.

You may be interested in this : http://www.blitzbasic.com/Community/posts.php?topic=82448

Hardcoal

(Posted 2015) [#4]

I'll check the link later remi tnx
And Matty too

So Particle Effects are made by cloning sprites?
Are cloning sprites faster then cloning a 3d textured cube?

I made my engine by cloning mesh
But I suspect sprites are faster..

Matty

(Posted 2015) [#5]

Using an entire cube is pretty wasteful in 99.9 percent of cases.

There are different techniques these days with blitz3d / directx7 rectangular quads (2 tris) which share the same surface are the way to go for speed.

Sprites will work fine until you find that performance is becoming an issue. However if you arent using too many (in other words performance is fine on your target device) then use them.

The only time I would a cube as a particle is if I wanted a particular rffect that I couldnt achieve another way.

Hardcoal

(Posted 2015) [#6]

U say sprites are heavier then a 2 tris shape?

I thought sprites are made for speed..

For example vegetation on a terrain, arnt they sprites?

RemiD

(Posted 2015) [#7]

On all computers that i have tested my prototypes/demos/templates on, using seperate meshes/surfaces (copymesh) is slower than using copies of entities (copyentity) and is slower than using one mesh/surface.

An example :

Graphics3D(800,600,32,2)
SetBuffer(BackBuffer())

SeedRnd(MilliSecs())

Global Camera = CreateCamera()
CameraRange(Camera,0.1,100)
PositionEntity(Camera,0,1.65,0)

DLight = CreateLight(1)
LightColor(DLight,250,250,250)
PositionEntity(DLight,0,-1000,1000)
RotateEntity(DLight,45,0,0)

AmbientLight(050,050,050)

XMesh = CreateCube()
ScaleMesh(XMesh,1.0/2,1.0/2,1.0/2)
PositionMesh(XMesh,0,1.0/2,0)
HideEntity(XMesh)
DebugLog("SurfacesCount = "+CountSurfaces(XMesh))
DebugLog("VerticesCount = "+CountVertices(GetSurface(XMesh,1)))
DebugLog("TrianglesCount = "+CountTriangles(GetSurface(XMesh,1)))

MaxCountV% = Floor(32000.0/CountVertices(GetSurface(XMesh,1)))
DebugLog("MaxCountV = "+MaxCountV)

MaxCountT% = Floor(32000.0/CountTriangles(GetSurface(XMesh,1)))
DebugLog("MaxCountT = "+MaxCountT)

If(MaxCountV < MaxCountT)
 MaxCount% = MaxCountV
ElseIf(MaxCountT < MaxCountV)
 MaxCount% = MaxCountT
Else
 MaxCount% = MaxCountV
EndIf
DebugLog("MaxCount = "+MaxCount)

Global ThingsCount%
Dim ThingMesh(MaxCount)

Global AreaMesh = CreateMesh()

;test to display meshes with copymesh (separate meshes)
ThingsCount = 0
For i% = 1 To MaxCount
 ThingsCount = ThingsCount + 1
 Id% = ThingsCount
 ThingMesh(Id) = CopyMesh(XMesh)
 RotateMesh(ThingMesh(Id),0,Rnd(-180,180),0)
 PositionMesh(ThingMesh(Id),Rnd(-10,10),Rnd(-7.5,7.5),Rnd(15,100-0.51))
Next

RenderStart% = MilliSecs()
RenderWorld()
RenderTime% = MilliSecs() - RenderStart
Color(255,255,255)
Text(0,0,"Triangles = "+TrisRendered())
Text(0,20,"RenderTime with separate meshes = "+RenderTime)
Text(0,40,"Press any key to continue")
Flip()
WaitKey()

For Id% = 1 To ThingsCount
 FreeEntity(ThingMesh(Id))
 ThingMesh(Id) = 0
Next

;test to display meshes with copyentity (copies of a mesh)
ThingsCount = 0
For i% = 1 To MaxCount
 ThingsCount = ThingsCount + 1
 Id% = ThingsCount
 ThingMesh(Id) = CopyEntity(XMesh)
 RotateEntity(ThingMesh(Id),0,Rnd(-180,180),0)
 PositionEntity(ThingMesh(Id),Rnd(-10,10),Rnd(-7.5,7.5),Rnd(15,100-0.51))
Next

RenderStart% = MilliSecs()
RenderWorld()
RenderTime% = MilliSecs() - RenderStart
Color(255,255,255)
Text(0,0,"Triangles = "+TrisRendered())
Text(0,20,"RenderTime with copies of a mesh = "+RenderTime)
Text(0,40,"Press any key to continue")
Flip()
WaitKey()

For Id% = 1 To ThingsCount
 FreeEntity(ThingMesh(Id))
 ThingMesh(Id) = 0
Next

;test to display meshes with merged meshes merged surfaces (one mesh with one surface)
ThingsCount = 0
For i% = 1 To MaxCount
 ThingsCount = ThingsCount + 1
 Id% = ThingsCount
 TMesh = CopyMesh(XMesh)
 RotateMesh(TMesh,0,Rnd(-180,180),0)
 PositionMesh(TMesh,Rnd(-10,10),Rnd(-7.5,7.5),Rnd(15,100-0.51))
 AddMesh(TMesh,AreaMesh)
 FreeEntity(TMesh)
Next

RenderStart% = MilliSecs()
RenderWorld()
RenderTime% = MilliSecs() - RenderStart
Color(255,255,255)
Text(0,0,"Triangles = "+TrisRendered())
Text(0,20,"RenderTime with meshes merged in one mesh with one surface = "+RenderTime)
Text(0,40,"Press any key to continue")
Flip()
WaitKey()

FreeEntity(AreaMesh)
AreaMesh = 0

End()

Hardcoal

(Posted 2015) [#8]

So bottom line.. Which is the goal of my questions..

What should I use for Particle engine?
For example how does ParticleFX works..?