How to make 1000 Cubes ?

Blitz3D Forums/Blitz3D Beginners Area/How to make 1000 Cubes ?

ChaseHatesEggs

(Posted 2015) [#1]

In a Problem I have to make 1000 Cubes inside a sphere and have them explode out the only issue I have is making 1000 Cubes.Help?

stayne

(Posted 2015) [#2]

For i = 1 to 1000
cube = CreateCube()
PositionEntity cube,x,y,z
Next

Someone smarter than me can elaborate on the positioning.

Guy Fawkes

(Posted 2015) [#3]

Graphics3D(800, 600, 0, 2)

    SetBuffer BackBuffer()

    SeedRnd Millisecs()

    Global max_cubes = 1000

    Dim mycubes(max_cubes)

        For i = 1 to max_cubes

            mycubes(i) = CreateCube()

            PositionEntity mycubes(i), Rnd(-150, 50), 1.001, Rnd(50, 150)
            RotateEntity mycubes(i), Rnd(-359.0, 359.0), Rnd(-359.0, 359.0), Rnd(-359.0, 359.0)

            EntityColor(mycubes(i), Rnd(0, 255), Rnd(0, 255), Rnd(0, 255))
            EntityAlpha(mycubes(i), Rnd(0.25, 1.0))

        Next

    While Not KeyDown(1)

        UpdateWorld()
        RenderWorld()

        Flip 0
        Delay 1

    Wend

End

Floyd

(Posted 2015) [#4]

The answer depends on the details of the problem.

Size and position of the sphere, size restrictions on cubes, can cubes overlap...

In any case we shouldn't be doing your school work.

RemiD

(Posted 2015) [#5]

@Guy Fawkes>>Some observations about your code :

-the variables "max_cubes" does not need to be a global

-you can rotate an entity from -180.0 to 180.0 not from -359.0 to 359.0

-updateworld() is useless in your code

-your indentation does not make sense, it should look more like this :

Graphics3D(800, 600, 0, 2)

SeedRnd Millisecs()

For i = min to max

	;do stuff

Next

While( not KeyDown(1) )

	;do stuff

	Setbuffer(backbuffer())
        RenderWorld()

        Flip(1)

Wend

End()

Do what you want with these advices...

@ChaseHatesEggs>>
you can use tformpoint() and rnd(min,max) to randomly position a cube inside a sphere.
or
randomly position the cube between rnd(minX,maxX),rnd(minY,maxY),rnd(minZ,maxZ), then check if the cube is inside the sphere with a distance check, if yes good, if no reposition this cube

stayne

(Posted 2015) [#6]

I was wondering why he put all 1000 of them at 1.001 on the Y axis.

Anyway - I just tossed OP a bone to get him started.

Matty

(Posted 2015) [#7]

Now....do you have to also arrange the cubes in a spherical arrangement with no overlaps?

There are a number of methods of doing this......

KronosUK

(Posted 2015) [#8]

Was feeling bored so threw this together

Graphics3D(1024, 768, 0, 2)

SeedRnd MilliSecs()

camera = CreateCamera() ; can't see anything without a camera!
MoveEntity camera, 0,0,-250

sphere = CreateSphere(32) ; our holding sphere
ScaleEntity sphere,50,50,50
EntityAlpha sphere,0.85

light = CreateLight()
MoveEntity light,0,100,-500

Global cubebase = CreateCube() ; our cube model
HideEntity cubebase

EntityParent camera,sphere

CreateCubes(1000)

Global explode=False

While Not KeyDown(1)
	
	If KeyHit(57) Then explode=True ; hit SPACE key To explode
	
	If explode = True Then MoveCubes()
	
	If KeyHit(19) Then ResetCubes() ; hit R key To reset cubes
	
	TurnEntity sphere,0,0.1,0
	
	UpdateWorld()
	RenderWorld()
	
	Flip 0
	
Wend

End


Type MyCube
	
	Field entity
	Field velx#
	Field vely#
	Field velz#
	Field speed#
	
End Type


Function CreateCubes(max_cubes)
	
		
	For i = 1 To max_cubes
		
		cube.mycube = New MyCube
		
		cube\entity = CopyEntity(cubebase)
		
		PositionCube(cube)
		EntityColor(cube\entity, Rnd(0, 255), Rnd(0, 255), Rnd(0, 255))
		
		;we want cubes to fly away from centre so calculate a vector, based on position from origin, and normalize it
		Local Hyp# =EntityDistance(cube\entity,cubebase) 
		cube\velx = EntityX(cube\entity)/Hyp
		cube\vely = EntityY(cube\entity)/Hyp
		cube\velz = EntityZ(cube\entity)/Hyp
		cube\speed = Rnd(5)
	Next
	
	
End Function	


Function MoveCubes()
	
	For c.MyCube = Each MyCube
		
		MoveEntity c\entity,c\speed*c\velx,c\speed*c\vely,c\speed*c\velz
		
	Next
	
End Function

Function ResetCubes()
	explode = False
	For c.mycube = Each MyCube
		PositionCube(c)	
	Next		
	
	
End Function	

Function PositionCube(c.MyCube) ; we want to create cube no more than 50 units from origin, to fit the sphere
	Local pivot=CreatePivot() ; create a pivot at the origin
	RotateEntity pivot,Rnd(360),Rnd(360),Rnd(360) ; make the pivot 'point' in a random direction
	MoveEntity pivot,0,0,50;Rnd(50) if you want cubes inside sphere
	PositionEntity c\entity, EntityX(pivot), EntityY(pivot), EntityZ(pivot)
	FreeEntity pivot
End Function

Guy Fawkes

(Posted 2015) [#9]

@RemiD: You can correct everything else, but do NOT tell ME how to space and / or tab my OWN CODE! You have absolutely NO right to do so! And if you do it again or smart off to me, I'm GOING to report it!

LineOf7s

(Posted 2015) [#10]

..to the Indent Police? The Tab League? The Spacing Institute?

stayne

(Posted 2015) [#11]

His little all caps stuff is cute. I still think it's Puki.

RemiD

(Posted 2015) [#12]

I would use a goto Line to prevent different cubes from overlapping :

.LineChooseCubePosition
;position the cube
;check if the cube is far enough from others cubes
;if yes
 ;good
;if no
 ;goto LineChooseCubePosition

but if you use this technique, be sure to not create too many cubes compared to the size of the empty space or it will be an endless loop !

Matty

(Posted 2015) [#13]

RemiD - if I knew how many cubes I had, their initial size, the size I wanted to fit them in....I'd simply calculate their correct position with a bit of mathematics and place them....no need to enter a potentially endless loop!

RemiD

(Posted 2015) [#14]

If you know the size of each cube and the size of the empty space, you can have an idea of approximately how many cubes you can fit in it so there will be no endless loop.
I often use this technique to position things randomly in a scene and there is no problem if you always underestimate the number of things that you can fit in a scene depending on the size of the thing and the size of the scene.
But i agree that this is not the best way.

ChaseHatesEggs

(Posted 2015) [#15]

Thanks All!
@Floyd The problem is more than just making the cubes I just didn't know how to go about it, thanks anyway.