How to create a shinny black cube?

Blitz3D Forums/Blitz3D Beginners Area/How to create a shinny black cube?

Rick Nasher

(Posted 2015) [#1]

Hi guys,

Pretty sure this is a beginners question so here goes:
I'm trying to create a black shiny cube like object, but failing to get it right.

I've noticed that for instance in Cellular the red blood cell torus, is easy to make shiny. I'm guessing due to amount of segments.
However I thought should also be possible to make a low poly cube shiny.
I know how to apply a cube map to give it a mirror/metallic shine, but that doesn't work on a deep black surface as far as I can see.

Any body have a clue?

RemiD

(Posted 2015) [#2]

If you only want the "shiny effect" when a light is near enough, you can use a subdivided cube :
for each face, instead of having 2 triangles, you would have 10x10x2 triangles
You can build a subdivided cube in a modeling program or inside blitz3d.
Then you need to modify the shininess of the cube surface either with entityshininess() or with brushshininess()
http://www.blitzbasic.com/b3ddocs/command.php?name=EntityShininess
http://www.blitzbasic.com/b3ddocs/command.php?name=BrushShininess

If you want reflections on the cube, you can use a precaptured cubemap.
See : http://www.blitzmax.com/codearcs/codearcs.php?code=1167
If you want to see reflections on the cube, the environment must have different shapes with different colors...

Rick Nasher

(Posted 2015) [#3]

Hi RemiD.

Best I came up with sofar is a modified version of the SetCubeMode example[/a] from the Blitz3d help files..
C:\Program Files (x86)\Blitz3D\help\commands\3d_commands\SetCubeMode.htm

; SetCubeMode Example
; -------------------

width=640
height=480
depth=0
mode=0

Graphics3D width,height,depth,mode
SetBuffer BackBuffer()

; If user's graphics card does not support cubic mapping then quit example
If GfxDriverCaps3D()<110 Then RuntimeError "Sorry, your graphics card does not support cubic environemnt maps."

cam=CreateCamera()
PositionEntity cam,0,10,-10

; Create separate camera for updating cube map - this allows us to manipulate main camera and cube camera which avoids any confusion
cube_cam=CreateCamera()
HideEntity cube_cam

light=CreateLight()
RotateEntity light,90,0,0





;Create the Monolith.
Monolith=CreateCube()
EntityShininess Monolith,1
;EntityShininess Monolith,1
;EntityFX Monolith,1


;EntityColor Monolith,0,0,0 
PositionEntity Monolith,0,5,0
;PointEntity Monolith,prnt 
;ScaleEntity Monolith, 2*5,5*5,.5*5	
ScaleEntity Monolith, 2,5,.5	

Inside=CopyEntity(Monolith)
;ScaleEntity Inside, 1.99,4.99,.49
;ScaleEntity Inside, 1,4,.4
ScaleEntity Inside, 2,5,.5	
EntityColor Inside,0,0,0 
;EntityShininess Inside,1



EntityAlpha Monolith,.2
; Load object we will apply cubemap to - the classic teapot
;teapot=LoadMesh("media/teapot.x")

;shutle
;teapot=LoadMesh("GFX\286428main_shuttle-hi-res\shutD2F3.b3d")
;ScaleEntity teapot,.003,.003,.003

teapot=Monolith

;ScaleEntity teapot,.003,.003,.003
;PositionEntity teapot,0,10,0

; Create some scenery

; ground
ground=CreatePlane()
EntityColor ground,168,133,55
ground_tex=LoadTexture("media/sand.bmp")
ScaleTexture ground_tex,10,10
EntityTexture ground,ground_tex

; sky
sky=CreateSphere(24)
ScaleEntity sky,500,500,500
FlipMesh sky
EntityFX sky,1
sky_tex=LoadTexture("media/sky.bmp")
EntityTexture sky,sky_tex

; cactus
cactus=LoadMesh("media/cactus2.x")
FitMesh cactus,-5,0,-5,2,6,.5

; camel
camel=LoadMesh("media/camel.x")
EntityShininess camel,.9
FitMesh camel,5,0,-5,6,5,4


; Load ufo to give us a dynamic moving object that the cubemap will be able to reflect
ufo_piv=CreatePivot()
PositionEntity ufo_piv,0,15,0
ufo=LoadMesh("media/green_ufo.x",ufo_piv)
PositionEntity ufo,0,0,10


; Create texture with color + cubic environment map + store in vram flags
tex=CreateTexture(256,256,1+128+256)

; Apply cubic environment map to teapot
EntityTexture teapot,tex

; Set initial cube mode value
cube_mode=1

While Not KeyDown(1)

	; Control camera
	
	; mouse look
	
	mxs#=mxs#+(MouseXSpeed()/5.0)
	mys#=mys#+(MouseYSpeed()/5.0)

	RotateEntity cam,mys#,-mxs#,0

	MoveMouse width/2,height/2

	; move camera forwards/backwards/left/right with cursor keys
	
	If KeyDown(200)=True Then MoveEntity cam,0,0,.2 ; move camera forward
	If KeyDown(208)=True Then MoveEntity cam,0,0,-.2 ; move camera back

	If KeyDown(205)=True Then MoveEntity cam,.2,0,0 ; move camera left
	If KeyDown(203)=True Then MoveEntity cam,-.2,0,0 ; move camera right
	
	; If M key pressed then change cube mode
	If KeyHit(50)
		cube_mode=cube_mode+1
		If cube_mode=4 Then cube_mode=1
		SetCubeMode tex,cube_mode
	EndIf
	
	; Turn ufo pivot, causing child ufo mesh to spin around it (and teapot)
	TurnEntity ufo_piv,0,2,0

	; Hide our main camera before updating cube map - we don't need it to be rendererd every time cube_cam is rendered
	HideEntity cam

	; Update cubemap
	UpdateCubemap(tex,cube_cam,teapot)
	;UpdateCubemap(tex,cam,teapot)

	; Show main camera again
	ShowEntity cam

	RenderWorld
	
	Text 0,0,"Use mouse to look around"
	Text 0,20,"Use cursor keys to change camera position"
	Text 0,40,"Press M to change cube mode"
	Text 0,60,"SetCubeMode tex,"+cube_mode
	
	Flip

Wend


Function UpdateCubemap(tex,camera,entity)

	tex_sz=TextureWidth(tex)

	; Show the camera we have specifically created for updating the cubemap
	ShowEntity camera
	
	; Hide entity that will have cubemap applied to it. This is so we can get cubemap from its position, without it blocking the view
	HideEntity entity

	; Position camera where the entity is - this is where we will be rendering views from for cubemap
	PositionEntity camera,EntityX#(entity),EntityY#(entity),EntityZ#(entity)

	CameraClsMode camera,False,True
	
	; Set the camera's viewport so it is the same size as our texture - so we can fit entire screen contents into texture
	CameraViewport camera,0,0,tex_sz,tex_sz

	; Update cubemap

	; do left view	
	SetCubeFace tex,0
	RotateEntity camera,0,90,0
	RenderWorld
	CopyRect 0,0,tex_sz,tex_sz,0,0,BackBuffer(),TextureBuffer(tex)
	
	; do forward view
	SetCubeFace tex,1
	RotateEntity camera,0,0,0
	RenderWorld
	CopyRect 0,0,tex_sz,tex_sz,0,0,BackBuffer(),TextureBuffer(tex)
	
	; do right view	
	SetCubeFace tex,2
	RotateEntity camera,0,-90,0
	RenderWorld
	CopyRect 0,0,tex_sz,tex_sz,0,0,BackBuffer(),TextureBuffer(tex)
	
	; do backward view
	SetCubeFace tex,3
	RotateEntity camera,0,180,0
	RenderWorld
	CopyRect 0,0,tex_sz,tex_sz,0,0,BackBuffer(),TextureBuffer(tex)
	
	; do up view
	SetCubeFace tex,4
	RotateEntity camera,-90,0,0
	RenderWorld
	CopyRect 0,0,tex_sz,tex_sz,0,0,BackBuffer(),TextureBuffer(tex)
	
	; do down view
	SetCubeFace tex,5
	RotateEntity camera,90,0,0
	RenderWorld
	CopyRect 0,0,tex_sz,tex_sz,0,0,BackBuffer(),TextureBuffer(tex)
	
	; Show entity again
	ShowEntity entity
	
	; Hide the cubemap camera
	HideEntity camera
	
End Function

But this is not satisfying(enough). Your suggestion of increasing the triangles is probably the only correct solution. Many thanks.

RemiD

(Posted 2015) [#4]

Another way to produce a fake reflection / fake shininess effect is to add another texture over the texture of the cube, and to use positiontexture() to move the texture depending on the camera movement.

RemiD

(Posted 2015) [#5]

It depends on the effect that you want. I remember than in the game "Drakan" the shininess of the gems was made by creating particles (like small suns) on different triangles which progressively increased in size and then were deleted. Very nice effect.

Here : https://www.youtube.com/v/fXDo7Fta4Ig?start=904&end=960

_PJ_	(Posted 2015) [#6]

Using the built-in reflection map filters can do this simply and effectively.
Applying the second texture with flag 64 will update the display of the texture depending on the view without the need to modify positiontexture each frame.

Rick Nasher

(Posted 2015) [#7]

Thanks for your suggestions guys.

@ _PJ_:
Flag 64 = Spherical environment map. I've never seen that in action. Actually, before I resorted to the cube mapping solution I was trying to find some code for spherical mapping, but was put off by people stating couldn't be used in Blitz. Now I'm thinking they may have not been using as intended.

Do you have a little example for this? What should the second texture look like?

RemiD

(Posted 2015) [#8]

There are some examples of spherical environment map in the Blitz3d samples. But from my tests it will look good only on a mesh with a complex shape. (=not a cube)

Rick Nasher

(Posted 2015) [#9]

Ah, that's a pity. Sounded almost too good. lol

RemiD

(Posted 2015) [#10]

If i remember correctly, with a spheremap you cannot use only a precapture of the environment because then the same texture is used whatever the position that the camera is, so if you look at the shape and it shows something behind or at left or at right of the shape, the reflection will appear weird...

With a cubemap you can use a precapture (6 precaptures : front, back, left, right, top, bottom) and then only the turning moving entities will not be shown on the reflection, but the reflection will appear convincing enough.

Rick Nasher

(Posted 2015) [#11]

Given _PJ_'s comment I was under the impression that I missed something and the sphere mapping was the default automatic function of Blitz3d and cube mapping the more advanced version.

RemiD

(Posted 2015) [#12]

this may give you some ideas :
Blitz3D\samples\mak\multi_tex

Rick Nasher

(Posted 2015) [#13]

Many thanks RemiD. Gave it a try and appears you are right.

Rick Nasher

(Posted 2015) [#14]

Solution.
(Just added for completeness and anyone interested. Please don't comment on the messy code; didn't bother to clean or anything.)
Thanks to the guys who contributed to sorting this out.

; SetCubeMode Example
; -------------------

width=640
height=480
depth=0
mode=0

Graphics3D width,height,depth,mode
SetBuffer BackBuffer()

; If user's graphics card does not support cubic mapping then quit example
If GfxDriverCaps3D()<110 Then RuntimeError "Sorry, your graphics card does not support cubic environemnt maps."

cam=CreateCamera()
PositionEntity cam,0,10,-10

; Create separate camera for updating cube map - this allows us to manipulate main camera and cube camera which avoids any confusion
cube_cam=CreateCamera()
HideEntity cube_cam

light=CreateLight()
RotateEntity light,90,0,0





;Create the Monolith.
;Monolith=CreateCube()
Monolith=LoadMesh ("Monolith1.b3d")

EntityShininess Monolith,1



;EntityColor Monolith,0,0,0 
PositionEntity Monolith,0,5,2
;ScaleEntity Monolith, 2,5,.5	
ScaleEntity Monolith,.1,.1,.1


MonoCopy=CopyEntity (Monolith)
PositionEntity MonoCopy,-7,5,2
EntityColor MonoCopy,0,0,0 
EntityShininess MonoCopy,1


Horizlight=CreateLight()
RotateEntity Horizlight,0,0,0
PositionEntity Horizlight,0,5,20


;Inside=CopyEntity(Monolith)
;ScaleEntity Inside, 2,5,.5	
;EntityColor Inside,0,0,0 

;HideEntity Inside

;EntityAlpha Monolith,.9

; Load object we will apply cubemap to - the classic teapot
;teapot=LoadMesh("media/teapot.x")

;shutle
;teapot=LoadMesh("GFX\286428main_shuttle-hi-res\shutD2F3.b3d")
;ScaleEntity teapot,.003,.003,.003

teapot=Monolith

;ScaleEntity teapot,.003,.003,.003
;PositionEntity teapot,0,10,0



;== Create some scenery ==

; ground
ground=CreatePlane()
EntityColor ground,168,133,55
ground_tex=LoadTexture("media/sand.bmp")
ScaleTexture ground_tex,10,10
EntityTexture ground,ground_tex

; sky
sky=CreateSphere(24)
ScaleEntity sky,500,500,500
FlipMesh sky
EntityFX sky,1
sky_tex=LoadTexture("media/sky.bmp")
EntityTexture sky,sky_tex

; cactus
cactus=LoadMesh("media/cactus2.x")
FitMesh cactus,-5,0,-5,2,6,.5

; camel
camel=LoadMesh("media/camel.x")
EntityShininess camel,.9
FitMesh camel,5,0,-5,6,5,4


; Load ufo to give us a dynamic moving object that the cubemap will be able to reflect
ufo_piv=CreatePivot()
PositionEntity ufo_piv,0,10,0
ufo=LoadMesh("media/green_ufo.x",ufo_piv)
PositionEntity ufo,0,0,10


;Load base texture
;basetex=LoadTexture( "blitzlogo.bmp" )
basetex=CreateTexture( 64,64,0 )
;ScaleTexture basetex,.5,.5

SetBuffer TextureBuffer(basetex)
ClsColor 0,0,0
Cls
Color 20,20,20:Rect 0,0,64,64




; Create texture with color + cubic environment map + store in vram flags
tex=CreateTexture(256,256,1+128+256) ;  1 =color + 128= cubemap + 256=vram


; Apply cubic environment map to teapot

EntityTexture teapot,basetex,0,0
EntityTexture teapot,tex,0,1

TextureBlend basetex,2
TextureBlend tex,5

SetBuffer BackBuffer()
; Set initial cube mode value
cube_mode=1

While Not KeyDown(1)

	; Control camera
	
	; mouse look
	
	mxs#=mxs#+(MouseXSpeed()/5.0)
	mys#=mys#+(MouseYSpeed()/5.0)

	RotateEntity cam,mys#,-mxs#,0

	MoveMouse width/2,height/2

	; move camera forwards/backwards/left/right with cursor keys
	
	If KeyDown(200)=True Then MoveEntity cam,0,0,.2 ; move camera forward
	If KeyDown(208)=True Then MoveEntity cam,0,0,-.2 ; move camera back

	If KeyDown(205)=True Then MoveEntity cam,.2,0,0 ; move camera left
	If KeyDown(203)=True Then MoveEntity cam,-.2,0,0 ; move camera right
	
	; If M key pressed then change cube mode
	If KeyHit(50)
		cube_mode=cube_mode+1
		If cube_mode=4 Then cube_mode=1
		SetCubeMode tex,cube_mode
	EndIf
	
	; Turn ufo pivot, causing child ufo mesh to spin around it (and teapot)
	TurnEntity ufo_piv,0,2,0

	; Hide our main camera before updating cube map - we don't need it to be rendererd every time cube_cam is rendered
	HideEntity cam

	; Update cubemap
	UpdateCubemap(tex,cube_cam,teapot)
	;UpdateCubemap(tex,cam,teapot)

	; Show main camera again
	ShowEntity cam

	RenderWorld
	
	Text 0,0,"Use mouse to look around"
	Text 0,20,"Use cursor keys to change camera position"
	Text 0,40,"Press M to change cube mode"
	Text 0,60,"SetCubeMode tex,"+cube_mode
	
	Flip

Wend


Function UpdateCubemap(tex,camera,entity)

	tex_sz=TextureWidth(tex)

	; Show the camera we have specifically created for updating the cubemap
	ShowEntity camera
	
	; Hide entity that will have cubemap applied to it. This is so we can get cubemap from its position, without it blocking the view
	HideEntity entity

	; Position camera where the entity is - this is where we will be rendering views from for cubemap
	PositionEntity camera,EntityX#(entity),EntityY#(entity),EntityZ#(entity)

	CameraClsMode camera,False,True
	
	; Set the camera's viewport so it is the same size as our texture - so we can fit entire screen contents into texture
	CameraViewport camera,0,0,tex_sz,tex_sz

	; Update cubemap

	; do left view	
	SetCubeFace tex,0
	RotateEntity camera,0,90,0
	RenderWorld
	CopyRect 0,0,tex_sz,tex_sz,0,0,BackBuffer(),TextureBuffer(tex)
	
	; do forward view
	SetCubeFace tex,1
	RotateEntity camera,0,0,0
	RenderWorld
	CopyRect 0,0,tex_sz,tex_sz,0,0,BackBuffer(),TextureBuffer(tex)
	
	; do right view	
	SetCubeFace tex,2
	RotateEntity camera,0,-90,0
	RenderWorld
	CopyRect 0,0,tex_sz,tex_sz,0,0,BackBuffer(),TextureBuffer(tex)
	
	; do backward view
	SetCubeFace tex,3
	RotateEntity camera,0,180,0
	RenderWorld
	CopyRect 0,0,tex_sz,tex_sz,0,0,BackBuffer(),TextureBuffer(tex)
	
	; do up view
	SetCubeFace tex,4
	RotateEntity camera,-90,0,0
	RenderWorld
	CopyRect 0,0,tex_sz,tex_sz,0,0,BackBuffer(),TextureBuffer(tex)
	
	; do down view
	SetCubeFace tex,5
	RotateEntity camera,90,0,0
	RenderWorld
	CopyRect 0,0,tex_sz,tex_sz,0,0,BackBuffer(),TextureBuffer(tex)
	
	; Show entity again
	ShowEntity entity
	
	; Hide the cubemap camera
	HideEntity camera
	
End Function

Media required): a box model(link) with more triangles then the standard cube.

*Above example was derived from: "C:\Program Files (x86)\Blitz3D\help\commands\3d_examples\SetCubeMode.bb" and rest of media can be found there in the media folder. (need to adjust to your path to blitz of course)