Trouble drawing

Blitz3D Forums/Blitz3D Beginners Area/Trouble drawing

Guy Fawkes

(Posted 2014) [#1]

Hello all. As I progress forward in my program, I now need a working, NON-looping version of "api_messagebox()". So I decided to create one. Problem is, the image seems to be invisible no matter what I do & I don't know why.

Can someone please help me make my image become visible?

Here's the code so far:

;application title
AppTitle "Yes / No / Cancel / Drag Demo"

;windowed mode
Graphics3D 800, 600, 0, 2
SetBuffer BackBuffer()
SeedRnd MilliSecs()

Global cam = CreateCamera()
PositionEntity cam, 0, 1, 0
CameraRange cam, .01, 10000.0

;global arrays declared in main program
Dim mouse_selection_area(3, 3)

Global win = draw_win_popup("Are you sure you wish to quit?", "YES", "NO", "CANCEL")

api_ShowWindow(SystemProperty$("AppHWND"), 1)

	While Not KeyDown(1)
	
		;call of the function
		retcode = update_win_popup(win)
		
		UpdateWorld
		RenderWorld

		DrawImage(win, GraphicsWidth()/2, GraphicsHeight()/2)

		;save the window image if need be
		If KeyHit(57) Then Save_Image_To_File(win, "window.bmp")

		Color 255, 255, 255
		Text 10, 10, "retcode: "+retcode

		VWait 1
		Flip 0
		Delay 1
	
	Wend

End

;==================================================================================
Function draw_win_popup(title$, but1_caption$="", but2_caption$="", but3_caption$="")

	;----------------------------------------------------------------------------------
	;displays a window and waits for a mouse click on a button or dragging the window
	;in the window title or nothing to be selected
	;works only in windowed mode
	;----------------------------------------------------------------------------------
	;parameters | title$ = The title of the window to be displayed in the window bar
	;----------------------------------------------------------------------------------
	;returned value:
	;a number that represents the button pressed (1..3)
	;or 0 if none were pressed
	;----------------------------------------------------------------------------------
	
	;buttons vars
	Local button_width = 70 ;width of each button
	Local button_height = 30 ;height of each button
	Local x_button ;starting x point for the first button
	Local y_button ;y for each button

	;set the window font
	Local window_font = LoadFont("arial.ttf", button_height/2, True)
	SetFont window_font
	
	;dimension of the window based on the lenght of the title
	Local window_width = StringWidth(title) + 100
	
	;height of the window (constant)
	Local window_height= 100

	;center a viewport on the screen
	Local window_x = (GraphicsWidth() - window_width)/2
	Local window_y = (GraphicsHeight() - window_height)/2
		
	;make the viewport bigger for the shadow
	Local shadow = 10
	Viewport (window_x-shadow,window_y-shadow,window_width+2*shadow,window_height+2*shadow)

	;create window image
	Local img = CreateImage(window_width, window_height)
	
	;offset the window to the "center"
	MidHandle img
	
	SetBuffer ImageBuffer(img)
		
		;draw a grey shadow
		Color 72,72,72
		Rect window_x+shadow,window_y+shadow,window_width,window_height,1
		
		;draw the window
		Color 192,192,192
		Rect window_x,window_y,window_width,window_height,1
		
		;draw the window bar
		Color 68,207,252
		Rect window_x+1,window_y+1,window_width-2,25,1
		
		;center the window title text to the window bar
		Color 0,0,0
		Text window_x + window_width/2 ,window_y+3, title, True
		
		;draw buttons
		x_button = window_x + 10 ;starting x point for the first button
		y_button = window_y + 50 ;y for each button
		
		;draw first button
		If but1_caption <> "" Then
	
			Color 0,0,0
			Rect x_button,y_button,button_width,button_height,0
			Text x_button + button_width/2, y_button+5,but1_caption,True
			
			;make the button 3d
			Color 255,255,255
			Line x_button,y_button,x_button + button_width - 1,y_button
			Line x_button,y_button,x_button,y_button + button_height - 1
			
			;memo the button coordinates in the array
			mouse_selection_area(1,1) = x_button
			mouse_selection_area(1,2) = y_button
	
		EndIf
		
		;determine the x position for the middle button
		x_button = window_x + window_width/2 - button_width/2
	
		;draw middle button
		If but2_caption <> "" Then
	
			Color 0,0,0
			Rect x_button,y_button,button_width,button_height,0
			Text x_button + button_width/2, y_button+5,but2_caption,True
		
			;make the button 3d
			Color 255,255,255
			Line x_button,y_button,x_button + button_width - 1,y_button
			Line x_button,y_button,x_button,y_button + button_height - 1
		
			;memo the button coordinates in the array
			mouse_selection_area(2,1) = x_button
			mouse_selection_area(2,2) = y_button
	
		EndIf
		
		;determine the x position for the third button
		x_button = window_x + window_width - button_width - 10
		
		;draw third button
		If but3_caption <> "" Then
	
			Color 0,0,0
			Rect x_button,y_button,button_width,button_height,0
			Text x_button + button_width/2, y_button+5,but3_caption,True
		
			;make the button 3d
			Color 255,255,255
			Line x_button,y_button,x_button + button_width - 1,y_button
			Line x_button,y_button,x_button,y_button + button_height - 1
		
			;memo the button coordinates in the array
			mouse_selection_area(3,1) = x_button
			mouse_selection_area(3,2) = y_button
	
		EndIf
	
	;reset the viewport
	Viewport 0, 0, GraphicsWidth(), GraphicsHeight()

	;set buffer back to normal
	SetBuffer BackBuffer()
	
	;free the font
	FreeFont window_font
		
	;return the image
	Return img

End Function
;----------------------------------------------------------------------------------

;==================================================================================
Function update_win_popup(img)

	;dimension of the window based on the lenght of the title
	Local window_width = StringWidth(title) + 100
	
	;height of the window (constant)
	Local window_height= 100
	
	;center a viewport on the screen
	Local window_x = (GraphicsWidth() - window_width)/2
	Local window_y = (GraphicsHeight() - window_height)/2
	
	;loop until we click on a button
	click = 0

	If MouseDown(1)
		
		For n = 1 To 3

			If (MouseX() > window_x+1) And (MouseX() < window_x+1+window_width-2)
				If (MouseY() > window_y+1) And (MouseY() < window_y+1+25)
					
					;drag window here
					
				EndIf
			EndIf

		Next

	EndIf
	
	;if click with the left button
	If MouseHit(1)

		;check all the buttons
		For n = 1 To 3

			;check if the mouse click was inside a button
			If (MouseX() > mouse_selection_area(n,1)) And (MouseX()< mouse_selection_area(n,1) + button_width) Then

				If (MouseY() > mouse_selection_area(n,2)) And (MouseY()< mouse_selection_area(n,2) + button_height) Then

					;acquire the button pressed
					click = n

					;fade out window here


					;exits from the for..next loop
					Exit
						
				EndIf
	
			EndIf
	
		Next
	
	EndIf

	;return the button pressed, or 0 if none of the buttons were pressed
	Return click

End Function
;----------------------------------------------------------------------------------

;==================================================================================
Function Save_Image_To_File(img, fi$)

	If FileType(fi$) Then DeleteFile(fi$)
	saved = SaveImage(img, fi$)
	Return saved

End Function

Thanks alot all!

Have a GREAT afternoon!

Sincerely,

~GF

Guy Fawkes

(Posted 2014) [#2]

Can someone please assist?

Thank You very much!

Have a GREAT evening!

Sincerely,

~GF

_PJ_	(Posted 2014) [#3]

If MouseHit(1)

;check all the buttons
For n = 1 To 3

Guy Fawkes

(Posted 2014) [#4]

Uh, PJ, Thanks but that doesn't help. :3 I simply need it to display my window.

Guy Fawkes

(Posted 2014) [#5]

Can someone please assist?

Thanks alot!

Have a GREAT evening!

Sincerely,

~GF

Floyd

(Posted 2014) [#6]

Your image IS being drawn. Unfortunately the image is solid black.

You can test this by adding one line of code, near line 175.

;set buffer back to normal
	Oval 20, 20, 50, 30
	SetBuffer BackBuffer()

Guy Fawkes

(Posted 2014) [#7]

Ok, so where exactly did I make it not draw and how can I fix it?

RemiD

(Posted 2014) [#8]

After you have done a modification on an image, you can debug it like this :

ClsColor(125,125,125)
Cls()
DrawImage(Image,0,0)
Flip()
WaitKey()

This will permit you to see how the image has been modified and what it looks like after the modification.

Guy Fawkes

(Posted 2014) [#9]

Just tried it. it's still not showing any image.

Guy Fawkes

(Posted 2014) [#10]

Gah, What exactly is making it turn black like that?

The above only showed like a gray image and nothing else.

Floyd

(Posted 2014) [#11]

You are confusing the window and the image. The x,y values in draw_win_popup() should be something like this:

	;center a viewport on the screen
	Local img = CreateImage(window_width, window_height)
	Local window_x = (ImageWidth(img) - window_width)/2
	Local window_y = (ImageHeight(img) - window_height)/2

Guy Fawkes

(Posted 2014) [#12]

Thank you so much, Floyd! That solved it!

Kudos to you, friend! :)

Sincerely,

~GF