I need some help with a for/next loop problem?

Blitz3D Forums/Blitz3D Beginners Area/I need some help with a for/next loop problem?

Newbie31

(Posted 2014) [#1]

Hello, I'm having a problem with for\next and would be much appreciative if someone could offer some advice on what I'm doing wrong.

I'm trying to make a program that opens an image a breaks it into 16 pieces and then shuffles them(I'm not very far along yet). Anyway the problem is I have 2 bits of code that I think should do the same thing.

The first one works as I want but will be harder to call later on.


For x = 0 To 3
	GrabImage gfxgrab[x],x*(ImageWidth(gfx_bg)/4),0*(ImageHeight(gfx_bg)/4)
	GrabImage gfxgrab[x+4],x*(ImageWidth(gfx_bg)/4),1*(ImageHeight(gfx_bg)/4)
	GrabImage gfxgrab[x+8],x*(ImageWidth(gfx_bg)/4),2*(ImageHeight(gfx_bg)/4)
	GrabImage gfxgrab[x+12],x*(ImageWidth(gfx_bg)/4),3*(ImageHeight(gfx_bg)/4)
Next

The second one just repeatedly grabs the one imagegrab.


For z = 0 To 15
	For x = 0 To 3
		For y = 0 To 3
			GrabImage gfxgrab[z],x*(ImageWidth(gfx_bg)/4),y*(ImageHeight(gfx_bg)/4)
		Next
	Next
Next

Should these bits of code do the same thing?

Complete Code:



.restart
;Set 2d Graphics
Graphics 1024,640,32,2
SetBuffer BackBuffer()

;Global setlev$ = Input("Select a level [a-z]?")		;Create a input so you can select a level
Global setlev$ = "b"									;Set Constant level for testing
;_________________________________________________
;______________Set Global Constraints_____________
;_________________________________________________

Global imX = 0		;Varible for Manipulating the Back ground image to allow scrolling if the image is larger than the graphics dimensions
Global imY = 0		;Varible for Manipulating the Back ground image to allow scrolling if the image is larger than the graphics dimensions


Global t = 0		;Set global varible for testing independant images


;Global Load Background Image
gfx_bg=LoadImage("_Images2\bg_image_"+setlev$+"01.jpg");Load the Background Image
gfx_bg1=LoadImage("_Images2\bg_image_"+setlev$+"01.jpg");Load the Background Image


;_________________________________________________________________________
;Create An Array to Load and Hold the image piece grabs
Const maximages = 17
Global gfxgrab[maximages%]

;This Creates 16 Empty Images That can be used to draw Image Grabs in.
For i = 0 To 15
	gfxgrab[i] = CreateImage(ImageWidth(gfx_bg)/4,ImageHeight(gfx_bg)/4)	
Next
;_________________________________________________________________________
;Draw Background Image
DrawImage gfx_bg,imX,imY	;This is important with out this the image grab does not heve a buffered image to draw from!

;Grab Images From the buffer and Assign them to the Array Update.
;For z = 0 To 15
;	For x = 0 To 3
;		For y = 0 To 3
;			GrabImage gfxgrab[z],x*(ImageWidth(gfx_bg)/4),y*(ImageHeight(gfx_bg)/4)
;		Next
;	Next
;Next

For x = 0 To 3
	GrabImage gfxgrab[x],x*(ImageWidth(gfx_bg)/4),0*(ImageHeight(gfx_bg)/4)
	GrabImage gfxgrab[x+4],x*(ImageWidth(gfx_bg)/4),1*(ImageHeight(gfx_bg)/4)
	GrabImage gfxgrab[x+8],x*(ImageWidth(gfx_bg)/4),2*(ImageHeight(gfx_bg)/4)
	GrabImage gfxgrab[x+12],x*(ImageWidth(gfx_bg)/4),3*(ImageHeight(gfx_bg)/4)
Next

;_________________________________________________
;___________________ CREATE TYPES ________________
;_________________________________________________
;Create a type to house the puzzle pieces.
Type square
	Field image
	Field ixpos
	Field iypos
End Type

;_________________________________________________
;___________________ Set Image Masks _____________
;_________________________________________________




;&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&
;&&&&&&&&&&&&&&&&&&& MAIN GAME AREA &&&&&&&&&&&&&&&&&&&&&&&&&
;&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&

Repeat
	Cls;Start with a clean BackBuffer.
	;If Player types to exit
	If setlev$ = "exit" Or setlev$ = "Exit" Or setlev$ = "EXIT" Or setlev$ = "close" Or setlev$ = "Close" Or setlev$ = "CLOSE"
		End
	End If
	
	;Create a End Game Key
	If KeyHit(1)
		End
	EndIf
	
	;Create a reset button
	If KeyHit( 19 ) = True
		Cls
		Goto restart
	EndIf	
	
	
	;DRAW IMAGES
	
	;-----------------------------------------------------------------------
	If KeyHit(6) And t<14
		t=t+1
	ElseIf KeyHit(5) And t>0
		t=t-1
	EndIf
	;	DrawImage gfxgrab[t],0*(ImageWidth(gfx_bg)/4),0*(ImageHeight(gfx_bg)/4)
	
	
	Local var0 = t
	DrawImage gfxgrab[var0],0*(ImageWidth(gfx_bg)/4),0*(ImageHeight(gfx_bg)/4)
	Local var1 = t+1
	DrawImage gfxgrab[var1],1*(ImageWidth(gfx_bg)/4),0*(ImageHeight(gfx_bg)/4)
	Local var2 = t+4
	DrawImage gfxgrab[var2],0*(ImageWidth(gfx_bg)/4),1*(ImageHeight(gfx_bg)/4)
	Local var3 = t+5
	DrawImage gfxgrab[var3],1*(ImageWidth(gfx_bg)/4),1*(ImageHeight(gfx_bg)/4)
	
;	For q = 0 To 15
;		For r = 0 To 3
;			For s = 0 To 3
;				DrawImage gfxgrab[q],r*(ImageWidth(gfx_bg)/4),s*(ImageHeight(gfx_bg)/4)
;			Next
;		Next
;	Next
	
	;-----------------------------------------------------------------------
	
;-----------------------------------------------------------------
;-------------- SET KEYBOARD AND MOUSE FUNCTIONS -----------------
;-----------------------------------------------------------------
	
	If KeyDown( 205 ) Or MouseX() > 650
		If imX>= -ImageWidth(gfx_bg) + GraphicsWidth() + 5
			imX=imX-10 ;Right Arrow1
		EndIf
	ElseIf KeyDown( 203 ) Or MouseX() < 150
		If imX<= -1
			imX=imX+10 ;Left Arrow
		EndIf
	ElseIf KeyDown( 208 ) Or MouseY() > 450
		If imY>= -ImageHeight(gfx_bg) + GraphicsHeight() + 5
			imY=imY-10 ;Up Arrow
		EndIf
	ElseIf KeyDown( 200 ) Or MouseY() < 150
		If imY<= -1 
			imY=imY+10 ;Down Arrow
		EndIf
	EndIf
	
;--------------------------------------------------------
;---------------- ONSCREEN TEXT AND HUD -----------------
;--------------------------------------------------------
	
	Color 255,255,255	
	;Display My Testing Text
	Text 0,(GraphicsHeight()/8)*7,"Mouse X Pos: " + MouseX() + " Mouse Y Pos: " + MouseY()
	Text 0,((GraphicsHeight()/8)*7)+15,"'t' varible: " + t
	
	Flip 
Until KeyDown(1)=1 ;End program when ESC is pressed


End 


;&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&
;&&&&&&&&&&&&&&&&&& END OF GAME AREA &&&&&&&&&&&&&&&&&
;&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&

;------------- CREATE GAME FUNCTIONS -----------------

Midimaster

(Posted 2014) [#2]

Your inner FOR/NEXT loop runs 16*4*4 times! And each z runs 16 times. The corresponding gfxgrab[z] image always gets the screenshot of the last
x,y-pair: 3/3.

It is it enought to run only 4x4 times and calculate z from x and y:

For x = 0 To 3
	For y = 0 To 3
		z%=y*4+x
		GrabImage gfxgrab[z],x*(ImageWidth(gfx_bg)/4),y*(ImageHeight(gfx_bg)/4)
	Next
Next

or calculate x,y from z:

For z=0 to 15
	x%=z mod 4
	y%=z/4
	GrabImage gfxgrab[z],x*(ImageWidth(gfx_bg)/4),y*(ImageHeight(gfx_bg)/4)
Next

Newbie31

(Posted 2014) [#3]

It didn't even occur to me to try and calculate z from x/y. But that was exactly what I was aiming for. Thanks for you help.