Help with LinePick

Blitz3D Forums/Blitz3D Beginners Area/Help with LinePick

Yue	(Posted 2014) [#1]

I could not quite understand how a LinePick, I remember that I spoke no English and use the google translator.

I would like a small example or something as detailed as in explanation.

A greeting.

Edit:
Ok, Trial and error the only way to learn.

Graphics3D 800,600,32,2
SetBuffer BackBuffer()


Local Camara% = CreateCamera()
Local Luz%    = CreateLight()
Local Cubo%   = CreateCube()

PositionEntity Camara%,0,0,-10
EntityPickMode Cubo%,2
While Not KeyDown(1)
	Local Linea% = LinePick(0,0,-10,0,0,10,0)
	UpdateWorld 
	
	If KeyDown(203) MoveEntity Cubo%, .1,0,0
		If KeyDown(205) MoveEntity Cubo%,-.1,0,0
	RenderWorld 
	
	Flip 
	
	AppTitle Linea%
Wend

feeble1

(Posted 2014) [#2]

I am not quite sure what you are trying to do. I hope this helps you out a bit.


Graphics3D 800,600,32,2
SetBuffer BackBuffer()

Global Camara% = CreateCamera()
Local Luz%    = CreateLight()
Local Cubo%   = CreateCube()
PositionEntity Camara%,0,0,-10
EntityPickMode Cubo%,2

Local mxspd#
Local myspd#

While Not KeyDown(1)
	;a line pick from the camera, could easily be replaced with a camerapick, if that is what you want
	;Press spacebar to pick!
	If KeyHit(57) Then Linea=LinePick(EntityX(Camara),EntityX(Camara),EntityZ(Camara),0,0,20,1)

	If KeyDown(203) MoveEntity Cubo%, .1,0,0
	If KeyDown(205) MoveEntity Cubo%,-.1,0,0
	If KeyDown(208) MoveEntity Cubo%,0,-.1,0
		
	UpdateWorld
	RenderWorld 
	
	Text 0,20,"Linea: "+Linea
	Text 0,40,"PickedX: "+PickedX#()
	Text 0,60,"PickedY: "+PickedY#()
	Text 0,80,"PickedZ: "+PickedZ#()
	Text 0,100,"PickedNX: "+PickedNX#()
	Text 0,120,"PickedNY: "+PickedNY#()
	Text 0,140,"PickedNZ: "+PickedNZ#()
	Text 0,160,"PickedTime: "+PickedTime#()
	Text 0,180,"PickedEntity: "+PickedEntity()
	Text 0,200,"PickedSurface: "+PickedSurface()
	Text 0,220,"PickedTriangle: "+PickedTriangle()
	Text 0,260,"Press SPACEBAR to pick"
	
	Flip 
	
	AppTitle Linea%
Wend
End

Matty

(Posted 2014) [#3]

A linepick is a way to detect if an entity is at a certain position.

Example:

Firing a gun at a target.

To check if the bullet hits the target you might use a line pick.
The initial coordinates would be the gun's global position. (first 3 parameters)

The vector would be the direction and length to check from that starting point (next 3 parameters).

The last parameter is the thickness of the 'bullet' you wish to use..

Imagine a cylinder pointing from the start point in the direction of the vector you supply with the thickness you supply. If it hits an entity which is marked with the correct pick type mode then it will return the handle to the entity.

Mikorians

(Posted 2014) [#4]

I couldn't make a line pick return anything but the entity number and had to switch to entitypick to get anywhere!

Kryzon

(Posted 2014) [#5]

Complementing what Matty has said, the linepick is really the "raycast" operation, common in many game engines.
If the 3D line that you specify with the parameters of the function intersects one or more of the pickable entities in your scene, the first of these picked entities has its contact information stored in the Picked(...) functions, like PickedX(), Y() and Z() for the position of the contact and PickedEntity() for returning the handle of the entity that was picked etc.

This is a simple example of AlignToVector that uses a linepick to retrieve the point of contact and the normal of the point of contact of the entity that was picked.

Graphics3D( 800, 600, 0, 2 )
SetBuffer BackBuffer()

Local FPSTimer	=	CreateTimer( 60 )
AmbientLight( 50, 50, 50 )
Color( 255, 255, 0 )

Local camera	=	CreateCamera()
					MoveEntity( camera, 0, 1, -3 )
					TurnEntity( camera, 10, 0, 0 )

Local bigSphere	=	CreateSphere( 64 )
					ScaleEntity( bigSphere, 4, 5, 4 )
					MoveEntity( bigSphere, 0, -5, 1 )
					;********************************
					EntityPickMode( bigSphere, 2 ) ;*
					;********************************

Local quad	=	CreateMesh()
				EntityColor( quad, 255, 0, 0 )
Local surf	=	CreateSurface( quad )
				AddVertex( surf, -0.5, 0.5, 0 )
				AddVertex( surf, 0.5, 0.5, 0 )
				AddVertex( surf, -0.5, -0.5, 0 )
				AddVertex( surf, 0.5, -0.5, 0 )
				AddTriangle( surf, 0, 1, 2 )
				AddTriangle( surf, 2, 1, 3 )
				UpdateNormals( quad )
				FlipMesh( quad )

Local linePickCone	=	CreateCone()
						ScaleEntity( linePickCone, 0.1, 0.3, 0.1 )
						TurnEntity( linePickCone, 0, 0, 180 )

Local light	=	CreateLight( 1 )
				MoveEntity( light, 15, 10, -15 )
				PointEntity( light, quad )

Local tempAngle = 0
Local tempX#,tempY#
Local tempPick

While Not KeyHit( 1 )
	WaitTimer( FPSTimer )
	Cls
	
	;UPDATE
	tempAngle = tempAngle + 1
	If tempAngle > 359 Then tempAngle = 0
	PositionEntity( linePickCone, 2.5 * Cos( tempAngle ), 2, 0 )
		
	;LINEPICK
	tempPick	=	LinePick( EntityX( linePickCone ), EntityY( linePickCone ), EntityZ( linePickCone ), 0, -100, 0 )
	If tempPick Then
		PositionEntity( quad, PickedX(), PickedY(), PickedZ() )
		AlignToVector( quad, PickedNX(), PickedNY(), PickedNZ(), 3, 0.3 ) ;0.3 for the smooth effect. 1.0 is an immediate change.
		MoveEntity( quad, 0, 0, 0.01 )
	EndIf 
	
	;RENDER
	UpdateWorld()
	RenderWorld()
	
	CameraProject( camera, EntityX( linePickCone ), EntityY( linePickCone ) - 0.25, EntityZ( linePickCone ) )
	tempX = ProjectedX() : tempY = ProjectedY()
	CameraProject( camera, PickedX(), PickedY(), PickedZ() )
	Line( tempX, tempY, ProjectedX(), ProjectedY() )
	Oval( ProjectedX() - 4, ProjectedY() - 4, 9, 9 )
	
	Flip
Wend

End

Mikorians

(Posted 2014) [#6]

I get pickedentity, and everything else CORRECT, but my loadanimmesh returns only
0,0,0 for pickedx,y,z - the MOST useful functions that I needed.
I carefully set up my linepick.
I also used entityxyz(e,TRUE) for the position, and a nice, long -y value above the shapes.
I'm using ver. 1.106

[EDIT]
Started working suddenly...
Wierd.

RGR	(Posted 2014) [#7]

There have been times when the computer was doing what coders had programmed ...

But those times are gone ... today they resist to do their job. They start working when they want ... what a world ...

.

Mikorians

(Posted 2014) [#8]

And well I remember those times!

(My object's top was also at y=0, doh!)