Texturemap scroller/flip/mirror tool

Blitz3D Forums/Blitz3D Beginners Area/Texturemap scroller/flip/mirror tool

Mikorians

(Posted 2014) [#1]

Texturemap scroller/flip/mirror tool...
Here's a funny little tool...

;BMP Scroller/Flipper/Mirror (not UVW, actual Pixels)
;An interesting/Silly tool to help make better tiles with...
;By Mikorians 19-Jan-2014
;Arrow keys: Scroll BMP
;Tab: Mode switch
;Mouse-L: Flip   Mouse-R: Mirror
Global t,Mde=0,totxs,totys
Const W=800
Const H=600
WH=W*0.5:HH=H*.5
WQ=W*0.0625:HQ=H*0.08333 ;For 'buttons'. @ 800x600 WQ & HQ = 50
Graphics3D W,H,0,0
c=CreateCamera()
l=CreateLight():TurnEntity l,45,45,0
a=CreateQuad():PositionEntity a,0,0,3

;Recreate/Load your skysphere/box entity here-
b=CreateSphere()
FlipMesh b
ScaleMesh b,5,5,5

t=LoadTexture("SkyBox.bmp",1)
EntityTexture a,t
EntityTexture b,t
HideEntity b

While Not KeyHit(1)
mxs1=0:mys1=0
If KeyDown(200) Then mys1=-1
If KeyDown(208) Then mys1=1
If KeyDown(203) Then mxs1=-1
If KeyDown(205) Then mxs1=1
If KeyHit(15) Then ;Tab
	Mde=Mde+1:If Mde>2 Then Mde=0
	If Mde=0 Or Mde=2 Then
		HideEntity b ;View 2D
		ShowEntity a
		If Mde=2 Then ScaleEntity a,.25,.25,.25 Else ScaleEntity a,1,1,1
	End If
	If Mde=1 Then
		HideEntity a ;View 3d
		ShowEntity b
	End If
End If

If Mde=1 Then
totxs=totxs+mxs1:totys=totys-mys1
RotateEntity b,0,totxs,0,True
TurnEntity b,totys,0,0,True
Goto Skp2D
End If

If KeyDown(200) Or KeyDown(208) Or KeyDown(205) Or KeyDown(203) Then MoveBMP mxs1,mys1

k=MouseHit(1)+(MouseHit(2)*2)
If k<>0 Then
x=MouseX():y=MouseY()
If x<WH Then qx=0 Else qx=1	;1 of 4 quadrants
If y<HH Then qy=0 Else qy=1
hf=0:vf=0
If qx=0 And x<WQ Then hf=-1		;directions and indications are...
If qx=0 And x>WH-WQ Then hf=1
If qx=1 And x<WH+WQ Then hf=-1
If qx=1 And x>W-WQ Then hf=1
If qy=0 And y<HQ Then vf=-1
If qy=0 And y>HH-HQ Then vf=1
If qy=1 And y<HH+HQ Then vf=-1
If qy=1 And y>H-HQ Then vf=1
;(Left button flips, Right button mirrors)
;Vertical Flips-----
;Whole Screen
If qx=0 And qy=0 And hf=1 And vf=-1 Then FlipVert
If qx=0 And qy=1 And hf=1 And vf=1 Then FlipVert
If qx=1 And qy=0 And hf=-1 And vf=-1 Then FlipVert
If qx=1 And qy=1 And hf=-1 And vf=1 Then FlipVert
;Left Half
If qx=0 And qy=0 And hf=0 And vf=-1 Then FlipLeft(k,qy)
If qx=0 And qy=1 And hf=0 And vf=1 Then FlipLeft(k,qy)
;Right Half
If qx=1 And qy=0 And hf=0 And vf=-1 Then FlipRight(k,qy)
If qx=1 And qy=1 And hf=0 And vf=1 Then FlipRight(k,qy)
;Horizontal Flips-----
;Whole Screen
If qx=0 And qy=0 And hf=-1 And vf=1 Then FlipHoriz
If qx=0 And qy=1 And hf=-1 And vf=-1 Then FlipHoriz
If qx=1 And qy=0 And hf=1 And vf=1 Then FlipHoriz
If qx=1 And qy=1 And hf=1 And vf=-1 Then FlipHoriz
;Top Half
If qx=0 And qy=0 And hf=-1 And vf=0 Then FlipTop(k,qx)
If qx=1 And qy=0 And hf=1 And vf=0 Then FlipTop(k,qx)
;Bottom Half
If qx=0 And qy=1 And hf=-1 And vf=0 Then FlipBot(k,qx)
If qx=1 And qy=1 And hf=1 And vf=0 Then FlipBot(k,qx)
End If
.Skp2D
UpdateWorld
If Mde=2 Then
	CameraClsMode(c,False,True)
	DrawTiles(W,H)
Else
	CameraClsMode(c,True,True)
End If
RenderWorld
If Mde=0 Or Mde=2 Then ;Crosshairs
	Line WH,0,WH,H
	Line 0,HH,W,HH
End If
Flip
Wend
SaveBuffer(TextureBuffer(T),"Skybox2.bmp")
End

Function FlipHoriz() ;Horizontally flip the entire page
AppTitle "Stand by..."
wi=TextureWidth(t):hi=TextureHeight(t)
f=CreateTexture(wi,hi,1)
For u=0 To hi-1
For v=0 To wi-1
co=ReadPixel(v,u,TextureBuffer(t))
WritePixel((wi-1)-v,u,co,TextureBuffer(f))
Next
Next
CopyRect 0,0,wi,hi,0,0,TextureBuffer(f),TextureBuffer(t)
FreeTexture f
AppTitle ""
End Function

Function FlipVert() ;Vertically flip the entire page
AppTitle "Stand by..."
wi=TextureWidth(t):hi=TextureHeight(t)
f=CreateTexture(wi,hi,1)
For u=0 To hi-1
For v=0 To wi-1
co=ReadPixel(v,u,TextureBuffer(t))
WritePixel(v,(hi-1)-u,co,TextureBuffer(f))
Next
Next
CopyRect 0,0,wi,hi,0,0,TextureBuffer(f),TextureBuffer(t)
FreeTexture f
AppTitle ""
End Function

Function FlipLeft(k,qy) ;Vertically flip the left half of the page (or mirror the right)
AppTitle "Stand by..."
wi=TextureWidth(t):hi=TextureHeight(t)
f=CreateTexture(wi,hi,1)
For u=0 To hi-1
For v=0 To wi-1
co=ReadPixel(v,u,TextureBuffer(t))
If k=1 Then ;Flip
	If v<(wi*.5) Then ;Left half
		WritePixel(v,(hi-1)-u,co,TextureBuffer(f))
	Else
		WritePixel(v,u,co,TextureBuffer(f))
	End If
Else ;Mirror
	If (u<(hi*.5) And qy=0) Or (u>(hi*.5)-1 And qy=1) Then ;Mirror top and bottom
		co=ReadPixel(v,(hi-1)-u,TextureBuffer(t))
		WritePixel(v,u,co,TextureBuffer(f))
	Else
		WritePixel(v,u,co,TextureBuffer(f))
	End If
End If
Next
Next
CopyRect 0,0,wi,hi,0,0,TextureBuffer(f),TextureBuffer(t)
FreeTexture f
AppTitle ""
End Function

Function FlipRight(k,qy) ;Vertically flip the right half of the page (or mirror the left)
AppTitle "Stand by..."
wi=TextureWidth(t):hi=TextureHeight(t)
f=CreateTexture(wi,hi,1)
For u=0 To hi-1
For v=0 To wi-1
co=ReadPixel(v,u,TextureBuffer(t))
If k=1 Then ;Flip
	If v>(wi*.5)-1 Then ;Left half
		WritePixel(v,(hi-1)-u,co,TextureBuffer(f))
	Else
		WritePixel(v,u,co,TextureBuffer(f))
	End If
Else ;Mirror
	If (u<(hi*.5) And qy=0) Or (u>(hi*.5)-1 And qy=1) Then ;Mirror top and bottom
		co=ReadPixel(v,(hi-1)-u,TextureBuffer(t))
		WritePixel(v,u,co,TextureBuffer(f))
	Else
		WritePixel(v,u,co,TextureBuffer(f))
	End If
End If
Next
Next
CopyRect 0,0,wi,hi,0,0,TextureBuffer(f),TextureBuffer(t)
FreeTexture f
AppTitle ""
End Function

Function FlipTop(k,qx) ;Horizontally flip the top half of the page (or mirror the bottom)
AppTitle "Stand by..."
wi=TextureWidth(t):hi=TextureHeight(t)
f=CreateTexture(wi,hi,1)
For u=0 To hi-1
For v=0 To wi-1
co=ReadPixel(v,u,TextureBuffer(t))
If k=1 Then ;Flip
	If u<(hi*.5) Then ;Left half
		WritePixel((wi-1)-v,u,co,TextureBuffer(f))
	Else
		WritePixel(v,u,co,TextureBuffer(f))
	End If
Else ;Mirror
	If (v<(wi*.5) And qx=0) Or (v>(wi*.5)-1 And qx=1) Then ;Mirror left and right
		co=ReadPixel((wi-1)-v,u,TextureBuffer(t))
		WritePixel(v,u,co,TextureBuffer(f))
	Else
		WritePixel(v,u,co,TextureBuffer(f))
	End If
End If
Next
Next
CopyRect 0,0,wi,hi,0,0,TextureBuffer(f),TextureBuffer(t)
FreeTexture f
AppTitle ""
End Function

Function FlipBot(k,qx) ;Horizontally flip the bottom half of the page (or mirror the top)
AppTitle "Stand by..."
wi=TextureWidth(t):hi=TextureHeight(t)
f=CreateTexture(wi,hi,1)
For u=0 To hi-1
For v=0 To wi-1
co=ReadPixel(v,u,TextureBuffer(t))
If k=1 Then ;Flip
	If u>(hi*.5)-1 Then ;Left half
		WritePixel((wi-1)-v,u,co,TextureBuffer(f))
	Else
		WritePixel(v,u,co,TextureBuffer(f))
	End If
Else ;Mirror
	If (v<(wi*.5) And qx=0) Or (v>(wi*.5)-1 And qx=1) Then ;Mirror left and right
		co=ReadPixel((wi-1)-v,u,TextureBuffer(t))
		WritePixel(v,u,co,TextureBuffer(f))
	Else
		WritePixel(v,u,co,TextureBuffer(f))
	End If
End If
Next
Next
CopyRect 0,0,wi,hi,0,0,TextureBuffer(f),TextureBuffer(t)
FreeTexture f
AppTitle ""
End Function

Function DrawTiles(W,H)
wi=TextureWidth(t):hi=TextureHeight(t)
m#=W/wi:n#=H/hi
For u=0 To n#
For v=0 To m#
CopyRect 0,0,wi,hi,v*wi,u*hi,TextureBuffer(t),BackBuffer()
Next
Next
End Function

Function MoveBMP(x,y)
AppTitle "Stand by..."
wi=TextureWidth(t):hi=TextureHeight(t)
f=CreateTexture(wi,hi,1)
For u=0 To hi-1
For v=0 To wi-1
px=v+x
py=u+y
If px<0 Then px=px+wi
If px>wi-1 Then px=px-wi
If py<0 Then py=py+hi
If py>hi-1 Then py=py-hi
co=ReadPixel(v,u,TextureBuffer(t))
WritePixel(px,py,co,TextureBuffer(f))
Next
Next
CopyRect 0,0,wi,hi,0,0,TextureBuffer(f),TextureBuffer(t)
FreeTexture f
AppTitle ""
End Function

Function CreateQuad()
Local v1,v2,v3,v4,v5,v6
mesh=CreateMesh()
s=CreateSurface(mesh)
v1=AddVertex(s,+2.0,+2,0.0,1,0)
v2=AddVertex(s,-2.0,-2,0.0,0,1)
v3=AddVertex(s,-2.0,+2,0.0,0,0)
v4=AddVertex(s,+2.0,+2,0.0,1,0)
v5=AddVertex(s,+2.0,-2,0.0,1,1)
v6=AddVertex(s,-2.0,-2,0.0,0,1)
Tri=AddTriangle(s,v1,v2,v3)
Tri=AddTriangle(s,v4,v5,v6)
UpdateNormals mesh
Return mesh
End Function

-----Copy the below text, save it as PasteMe.Hex - My HexRead.bb program decodes-----

SkyBox.jpg
1920002027
FFD8FFE000104A46494600010100000100010000FFDB004300140E0F120F0D14121012171514181E
32211E1C1C1E3D2C2E243249404C4B47404645505A736250556D5645466488656D777B8182814E60
8D978C7D96737E817CFFDB0043011517171E1A1E3B21213B7C5346537C7C7C7C7C7C7C7C7C7C7C7C
7C7C7C7C7C7C7C7C7C7C7C7C7C7C7C7C7C7C7C7C7C7C7C7C7C7C7C7C7C7C7C7C7C7C7C7C7C7CFFC0
0011080020002003012200021101031101FFC4001F00000105010101010101000000000000000001
02030405060708090A0BFFC400B5100002010303020403050504040000017D010203000411051221
31410613516107227114328191A1082342B1C11552D1F02433627282090A161718191A2526272829
2A3435363738393A434445464748494A535455565758595A636465666768696A737475767778797A
838485868788898A92939495969798999AA2A3A4A5A6A7A8A9AAB2B3B4B5B6B7B8B9BAC2C3C4C5C6
C7C8C9CAD2D3D4D5D6D7D8D9DAE1E2E3E4E5E6E7E8E9EAF1F2F3F4F5F6F7F8F9FAFFC4001F010003
0101010101010101010000000000000102030405060708090A0BFFC400B511000201020404030407
05040400010277000102031104052131061241510761711322328108144291A1B1C109233352F015
6272D10A162434E125F11718191A262728292A35363738393A434445464748494A53545556575859
5A636465666768696A737475767778797A82838485868788898A92939495969798999AA2A3A4A5A6
A7A8A9AAB2B3B4B5B6B7B8B9BAC2C3C4C5C6C7C8C9CAD2D3D4D5D6D7D8D9DAE2E3E4E5E6E7E8E9EA
F2F3F4F5F6F7F8F9FAFFDA000C03010002110311003F00C1C3363029D1F2707AD5910F00E78A89AD
D8313C0F4AD39909C5801956C75A84A90D9A9E3572318207D2A630154CF4349CD0469B2C379CCFB5
61FA62916D2F253955C0F7AEACC4A4E3029EA1546D00605727B57D0EA693DCE4D2D67046E6C1CE38
1564432270E81BDF15D13C5195C95182734EF2508076814B9DBDCA4D25A1FFD9