canvas graphics failing on deeply nested panels?

Archives Forums/MaxGUI Bug Reports/canvas graphics failing on deeply nested panels?

skn3	(Posted 2011) [#1]

Try this code:

Framework brl.GLMax2D
Import MaxGUI.Drivers
Import brl.Hook
Import brl.Timer
Import brl.System

Strict

Type TApplet 

	Method OnEvent(Event:TEvent) Abstract

	Method Run()
		AddHook EmitEventHook,eventhook,Self
	End Method

	Function eventhook:Object(id,data:Object,context:Object)
		Local event:TEvent = TEvent(data)
		Local app:TApplet = TApplet(context)
		app.OnEvent( event )
		Return data
	End Function

End Type

Type TSpinningApplet Extends TApplet
	
	Global image:TImage
	
	Field timer:TTimer
	Field Window:TGadget, canvas:TGadget
	
	Method Draw()
		
		SetGraphics CanvasGraphics(canvas)
		SetVirtualResolution ClientWidth(canvas),ClientHeight(canvas)
		SetViewport 0,0,ClientWidth(canvas), ClientHeight(canvas)
		
		SetBlend( ALPHABLEND )
		SetRotation( MilliSecs()*.1 )
		SetClsColor( 255, 0, 0 )
		
		Cls()
		DrawRect(GraphicsWidth()/2, GraphicsHeight()/2,50,50)
		
		Flip()
		
	End Method
	
	Method OnEvent(event:TEvent)
		If Not event Then Return 
		Select event.id
			Case EVENT_WINDOWCLOSE, EVENT_APPTERMINATE
				End
			Case EVENT_TIMERTICK
				RedrawGadget( canvas )
			Case EVENT_GADGETPAINT
				If (event.source = canvas) Then Draw()
		End Select
	End Method
	
	Method Create:TSpinningApplet(name$)
		Window = CreateWindow( name, 20, 20, 512, 512 )
		
		Local w = ClientWidth(window)
		Local h = ClientHeight(window)
		
		Local panel:TGadget
		panel = CreatePanel(0,0,w,h,Window,PANEL_RAISED)
		SetGadgetLayout( panel, EDGE_ALIGNED, EDGE_ALIGNED, EDGE_ALIGNED, EDGE_ALIGNED)
		
		For Local index = 0 Until 5
			panel = CreatePanel(0,0,panel.ClientWidth(),panel.ClientHeight(),panel,PANEL_RAISED)
			SetGadgetLayout( panel, EDGE_ALIGNED, EDGE_ALIGNED, EDGE_ALIGNED, EDGE_ALIGNED)
		Next
		
		canvas = CreateCanvas( 0, 0, w, h, panel )
		SetGadgetLayout( canvas, EDGE_ALIGNED, EDGE_ALIGNED, EDGE_ALIGNED, EDGE_ALIGNED )
		
		timer = CreateTimer( 100 )
		Run()
		
		Return Self
		
	End Method
	
End Type

AutoMidHandle True

Local spinner:TSpinningApplet = New TSpinningApplet.Create("Spinning Applet")

Repeat
	WaitSystem()
Forever

Everything works fine, you should see a rotating white box inside a canvas nested in many panels.

If you change the line

For Local index = 0 Until 5

For Local index = 0 Until 6

After nesting a canvas in 6 panels the gadget layout seems to fail. If you set it to even more panels nested (try 10) then it fails even worse!

Last edited 2011

skn3	(Posted 2011) [#2]

Does this have anything to do with it?

http://blogs.msdn.com/b/alejacma/archive/2008/11/20/controls-won-t-get-resized-once-the-nesting-hierarchy-of-windows-exceeds-a-certain-depth-x64.aspx

I am running windows 7 64bit...

Last edited 2011

shinkiro1

(Posted 2011) [#3]

I think it's a performance issue (MaxGUI is not very speed optimized)
On my latest generation iMac lag starts at 40 panels.

Last edited 2011

skn3	(Posted 2011) [#4]

I think it is a mix of both definitely. Sicne posting this I have had to remove the nested panels in my app and the broken behaviour corrects itself.

This is a windows only issue so you prob wont see it on OSX. If it is the same problem as described in the link then its infact an issue at the core of the windows kernal that has to be side stepped.

Crikey!

NoOdle

(Posted 2012) [#5]

This is a windows only issue so you prob wont see it on OSX. If it is the same problem as described in the link then its infact an issue at the core of the windows kernal that has to be side stepped.

Windows is an ugly beast. Thanks for the heads up, will need to bear this in mind when creating apps.