RequestFile - Mac - freezes window?

Archives Forums/BlitzMax Bug Reports/RequestFile - Mac - freezes window?

simonh

(Posted 2012) [#1]

Anyone else get this problem?

If I add this code to a standard windowed BlitzMax program:

If KeyHit( KEY_SPACE )
    Local def_dir$=CurrentDir$()
    Local filter$="Text File:txt"
    Local filename$=RequestFile$( "Please Select Text File",filter$,False,def_dir$ )	
EndIf

And press space to bring up the requestor, then cancel the requestor, the window will just freeze. However, the app appears to be running in the background.

If the save parameter is changed to true then it works fine.

Running Lion 10.7.4 and BlitzMax 1.48.

Last edited 2012

simonh

(Posted 2012) [#2]

Runnable example (overwrite simonh/fireworks sample)

Press space to bring up file requestor, then once it has closed, it should set off a firework.

' Fireworks by simonh

Strict

Global width=800
Global height=600

Graphics width,height,0

' Create a spark type
Type spark
	Field x#,y#,z#,vy#,xd#,yd#,zd#,r#,g#,b#,alpha#
End Type

' Load spark image
Global sparki:TImage=LoadImage("spark.png")

' Set no. of sparks to be created per firework
Global no_sparks=500

' Create spark list
Global spark_list:TList=New TList

' Load and set font
Global font:TImageFont=LoadImageFont("Arial.ttf",1)
SetImageFont font

' Start main loop
While Not KeyHit(KEY_ESCAPE)

	' If space key pressed then create new set of sparks (new firework)

	If KeyHit(KEY_SPACE)

		Local def_dir$=CurrentDir$()
		Local filter$="Text File:txt"
		Local filename$=RequestFile$( "Please Select Text File",filter$,False,def_dir$ )	
	
		Local x#=Rand(-100,100)
		Local y#=Rand(-100,100)
		Local z#=200

		Local r#=Rand(255)
		Local g#=Rand(255)
		Local b#=Rand(255)

		For Local i=1 To no_sparks

			Local speed# = 0.1

			Local ang1# = Rnd!(360)
			Local ang2# = Rnd!(360)

			Local sp:spark=New Spark
			spark_list.AddLast sp

			sp.x=x#
			sp.y=y#
			sp.z=z#

			sp.xd=Cos(ang1#)*Cos(ang2#)*speed#
			sp.yd=Cos(ang1#)*Sin(ang2#)*speed#
			sp.zd=Sin(ang1#)*speed#
	
			sp.r=r
			sp.g=g
			sp.b=b
	
			sp.alpha=1
	
		Next

	EndIf

	' Draw all sparks

	For Local sp:spark=EachIn spark_list

		' If spark alpha is above 0 then draw it...

		If sp.alpha>0

			sp.x=sp.x+sp.xd*10.0
			sp.y=sp.y+sp.yd*10.0
			sp.z=sp.z+sp.zd*10.0
			sp.y=sp.y+sp.vy#
			sp.vy=sp.vy+0.02

			' Calculate x and y draw values based on x,y,z co-ordinates
			Local x#=(width/2.0)+((sp.x/sp.z)*500)
			Local y#=(height/2.0)+((sp.y/sp.z)*500)

			sp.alpha=sp.alpha-0.01

			SetColor sp.r#,sp.g#,sp.b#
			SetBlend LIGHTBLEND
			SetAlpha sp.alpha
			SetScale 20/sp.z,20/sp.z
			DrawImage sparki,x#,y#

		'...else remove spark from spark list

		Else

			spark_list.Remove sp

		EndIf

	Next

	SetBlend SOLIDBLEND
	SetScale 1,1
	SetColor 255,255,255
	DrawText "Press space to ignite firework",0,0

	Flip
	Cls

Wend

Last edited 2012