Linux no-GUI problem

Archives Forums/BlitzMax Bug Reports/Linux no-GUI problem

BlitzSupport

(Posted 2011) [#1]

I'm playing with networking/sockets on an Ubuntu-based GUI-less server, so having to use Framework/Import to avoid bringing in graphics, sound, etc.

I wanted to print the current date and time to an incoming browser session, but as soon as I import BRL.System, I get a segmentation fault on running (no compiler errors).

I found that if I ripped CurrentDate and CurrentTime from BRL.System and called them directly (no longer importing BRL.System), it works fine.

I notice that BRL.System includes calls to obtain the desktop width/height, mouse control, file requesters, etc, and I'm assuming this is why it fails on a GUI-less Linux.

If so, would it be possible to move the system GUI stuff into a separate module, or not to include this if building/running in command-line mode?

Example...


Framework BRL.Socket

'Import BRL.System ' Segfault on Linux with no GUI!

Import BRL.Threads
Import BRL.StandardIO
Import BRL.SocketStream

SuperStrict

Local server:TSocket = CreateTCPSocket ()

If server

	If BindSocket (server, 9998)
	
		SocketListen server, 5
		
		Repeat
		
			Local client:TSocket = SocketAccept (server)
		
			If client			
				Local connectionthread:TThread = CreateThread (ProcessConnection, client)
			EndIf
			
			Delay 1000
			
		Forever	
	
	EndIf
	
	CloseSocket server
	
EndIf

Function ProcessConnection:Object (data:Object)

	Local client:TSocket = TSocket (data)

	If SocketConnected (client)
	
		Print "Got a new client at IP " + DottedIP (SocketRemoteIP (client))
	
		Local stream:TStream = CreateSocketStream (client)
		
		If stream
		
			Local incoming:String
			
			Repeat
				
				incoming = ReadLine (stream) ' Request from client's browser
				
'				If Left (Lower (incoming), 4) = "get "
'					If Instr (Lower (incoming), "exit")
'						CloseSocket client
'						Return Null
'					EndIf
'				EndIf
				
			Until incoming = ""

			' Acknowledge...
						
			WriteLine stream, "HTTP/1.1 200 OK"
			WriteLine stream, ""

			' Send data...

			WriteLine stream, "<HTML><TITLE>Hello, world!</TITLE><BODY>Hello, world! It's " + CurrentTime () + "!</BODY></HTML>"
			WriteLine stream, ""
			
			CloseStream stream
			
		EndIf

		CloseSocket client
		
	EndIf

End Function

' From BRL.System

Rem
bbdoc: Get current date
returns: The current date as a string
about:
Returns the current date in the format: DD MON YYYY (i.e. 10 DEC 2000).
End Rem
Function CurrentDate$()
	Local	time:Int[256],buff:Byte[256]
	time_(time)
	strftime_(buff,256,"%d %b %Y",localtime_( time ))
	Return String.FromCString(buff)
End Function

Rem
bbdoc: Get current time
returns: The current time as a string
about:
Returns the current time in the format: HH:MM:SS (i.e. 14:31:57).
End Rem
Function CurrentTime$()
	Local	time:Int[256],buff:Byte[256]
	time_(time)
	strftime_( buff,256,"%H:%M:%S",localtime_( time ) );
	Return String.FromCString(buff)
End Function