lists and threads, double buffered

Archives Forums/BlitzMax Bug Reports/lists and threads, double buffered

fredborg

(Posted 2010) [#1]

Hi,

I was testing some multi-threaded stuff in BMax, and it seems like there are a couple of problems. Which could be related to lists or arrays..

1. It crashes.

2. Clearing a list from the main thread doesn't seem to clear it correctly, if stuff was added to it from another thread.

Double buffered list, which crashes:

SuperStrict

SetGraphicsDriver GLMax2DDriver()
Graphics 640,480

Global quit:Int = False

Global mutex:TMutex[] = New TMutex[2]
Global list:TList[] = New TList[2]

list[0] = CreateList()
list[1] = CreateList()
mutex[0] = CreateMutex()
mutex[1] = CreateMutex()

Function ThreadFunc:Object( data:Object )
	
	Local k:Int = 0 
	Local side:Int = 0 
	
	While (quit = False)

		mutex[side].lock()
		
		' 
		' clearing from thread works .. until it crashes
		'
		list[side].clear()
		
		'
		' Add random junk to list
		'
		For Local x:Int = 0 Until 10
			Local s:String = "hello "+(k+x)
			list[side].addlast( s )
		Next
		mutex[side].unlock()
		
		side = 1 - side
		k :+ 1
	Wend
	
EndFunction

Local thread:TThread = CreateThread( ThreadFunc, Null )

Local side:Int = 0
Local total:Int = 0

While Not KeyHit(KEY_ESCAPE)
	
	Cls 
	
	mutex[side].lock()
	
	Local y:Int = 0
	For Local a:String = EachIn list[side]
		DrawText(a,10,y)
		y :+ 20
	Next
	DrawText "total: "+total,10,y+20
	
	'
	' this doesn't clear the list correctly..
	' list[side].clear()
	'
	
	mutex[side].unlock()
	
	side = 1-side
	total :+ 1 
	
	Flip False	
Wend

quit = True
WaitThread( thread )

Single list, which seems to work, except clearing the list from the main thread doesn't work correctly:

SuperStrict

SetGraphicsDriver GLMax2DDriver()
Graphics 640,480

Global quit:Int = False

Global mutex:TMutex = CreateMutex()
Global list:TList = CreateList()

Function ThreadFunc:Object( data:Object )
	
	Local k:Int = 0 
	Local side:Int = 0 
	
	While (quit = False)

		mutex.lock()
		
		' 
		' clearing from thread works .. 
		'
		list.clear()
		
		'
		' Add random junk to list
		'
		For Local x:Int = 0 Until 10
			Local s:String = "hello "+(k+x)
			list.addlast( s )
		Next
		mutex.unlock()
		
		side = 1 - side
		k :+ 1
	Wend
	
EndFunction

Local thread:TThread = CreateThread( ThreadFunc, Null )

Local side:Int = 0
Local total:Int = 0

While Not KeyHit(KEY_ESCAPE)
	
	Cls 
	
	mutex.lock()
	
	Local y:Int = 0
	For Local a:String = EachIn list
		DrawText(a,10,y)
		y :+ 20
	Next
	DrawText "total: "+total,10,y+20
	
	'
	' this doesn't clear the list correctly..
	'
	' list.clear()
	
	
	mutex.unlock()
	
	side = 1-side
	total :+ 1 
	
	Flip False	
Wend

quit = True
WaitThread( thread )

Edit: Apparently only debug mode suffers from the crash