Text() and non english characters

Archives Forums/Blitz3D Bug Reports/Text() and non english characters

Mr.Waterlily

(Posted 2007) [#1]

Hi,

I was playing a little with the Text() command and discovered something wierd.
If I create a boundary on the right side with Viewport, and use a loaded font(Arial), and the textstring includes non-english characters, the clipping doesn´t quite work properly.
Sometimes it can´t print non-complete letters.

Is this a known bug? Or did I just "get lucky"? ;)

I posted this in the Programming forum first but it should probably be located here instead.

Use the left and right arrows to see the "disappearing letter" bug.

Graphics 350,180,32,2
SetBuffer BackBuffer()
font=LoadFont("Arial",14,False,False,False)
SetFont font
tx=40
Repeat
	If KeyHit(203) Then tx=tx-5	;left
	If KeyHit(205) Then tx=tx+5	;Right
	Viewport 44,36,205,40
	Color 0,0,200
	Rect 44,36,205,40,1
	Color 255,255,255
	Text tx,40,"Alittetextstringthatcontainssomeletterthatiså;äandöandalsosomeüandÅagainandafterthatsomstandardenlishcharacters"
	Text tx,52,"Alittetextstringthatcontainssomeletterthatisonlystandartenglishlettagainandafterthatsomstandardenlishcharacters"
	Viewport 0,0,GraphicsWidth(),GraphicsHeight()
	Flip
Until KeyHit(1)
FreeFont font
End

Is there anything that can be done about this? And still be able to use the Text command?

Bobysait

(Posted 2012) [#2]

Got a problem with the text function on a similar (but different) behavior, I think the bug come from the same problem (in the bb internal sources)

when we create an image with stringwidth(txt$) as width, then we draw the text (txt$) inside, the last letter(s) are not drawn if the string contains some special caracters (but the rule seems really strange, because it only happens when the string contains some special chars and is terminated with a special chars)

Graphics 800,600,0,2
SetBuffer BackBuffer()

SetFont LoadFont("Arial",18)

DrawImage TxtImage("(é e)"),0,0
DrawImage TxtImage("(é é)"),0,20
DrawImage TxtImage("(é e 1"),0,40
DrawImage TxtImage("(é é 1"),0,60

; final characters to test :
Local chartest$="a10(),.!?@&é"

Local a
Color 255,255,255
For a=1 To Len(chartest)
	Local c$=Mid(chartest,a,1)
	; text drawn as it is supposed to be drawn
	Text 0,40*(a+1)+00, Asc(c) : DrawImage TxtImage("(é e 1) abc "+c),45,40*(a+1)+00
	; text that does not always draw the last char (simply replacing "e" with "é")
	Text 0,40*(a+1)+20, Asc(c) : DrawImage TxtImage("(é é 1) abc "+c),45,40*(a+1)+20
Next

Flip True

WaitKey
End

Function TxtImage(txt$)
	Local r=ColorRed(), g=ColorGreen(), b=ColorBlue(), cb=GraphicsBuffer()
	Local w=StringWidth(txt), h=StringHeight(txt)
	Local img=CreateImage(w,h)
	SetBuffer ImageBuffer(img)
	Color 255,255,255:Rect 0,0,w,h,1
	Color 020,000,000:Text 0,0,txt,0,0
	SetBuffer cb
	Color r,g,b
	Return img
End Function

for this problem, I had to make a little tweak to fix the code

Type hFont__
	Field name$, h, b,i,u, font
	Field cw[255],ch[255]
End Type

Global gDefHFont__.hFont__=HFont__(LoadHFont("Arial",12))
Global gCurHFont__.hFont__=gDefHFont__

Function HFont__.hFont__(font):Return Object.hFont__(font):End Function

Function LoadHFont(fontname$,height, bold=0,italic=0,underline=0)
	Local fnt=LoadFont(fontname,height,bold, italic,underline)
	SetFont fnt
	Local f.hFont__=New hFont__, b,c$
	f\name=fontname
	f\h=height
	f\b=bold
	f\i=italic
	f\u=underline
	f\font=fnt
	For b=1 To 255
		c=Chr(b)
		f\cw<b>=StringWidth(c)
		f\ch[b]=StringHeight(c)
	Next
	Return Handle(f)
End Function

Function SetHFont(font) : gCurHFont__=HFont__(font) : End Function

Function FreeHFont(font)
	Local f.hFont__=HFont__(font)
	If f=gDefHFont__ Then Return
	FreeFont f\font
	Delete f
End Function

Function HStringWidth(txt$)
	Local ln=Len(txt), c, b
	If ln<1 Then Return 0
	Local w=gCurHFont__\cw[Asc(Left(txt,1))]
	For c=2 To ln
		w=w+1+gCurHFont__\cw[Asc(Mid(txt,c,1))]
	Next
	Return w
End Function

Function HStringHeight(txt$)
	Local ln=Len(txt), c, b
	If ln<1 Then Return 0
	Local h=gCurHFont__\ch[Asc(Left(txt,1))], h2
	For c=2 To ln
		h2=gCurHFont__\cw[Asc(Mid(txt,c,1))]
		If h2>h Then h=h2
	Next
	Return h
End Function

Function HText(x,y,txt$,centerx=False,centery=False)
	Local ln=Len(txt), c, b, char$
	If centery Then y=y-HStringHeight(txt)*.5
	If centerx Then x=x-HStringWidth(txt)*.5
	For c=1 To ln
		char=Mid(txt,c,1)
		b=Asc(char)
		Text x,y,char,0,0
		x=x+gCurHFont__\cw[b]+1
	Next
End Function





Graphics 800,600,0,2
SetBuffer BackBuffer()

SetHFont LoadHFont("Arial",18)

DrawImage TxtImage("(é e)"),0,0
DrawImage TxtImage("(é é)"),0,20
DrawImage TxtImage("(é e 1"),0,40
DrawImage TxtImage("(é é 1"),0,60

; final characters to test :
Local chartest$="a10(),.!?@&é"

Local a
Color 255,255,255
For a=1 To Len(chartest)
	Local c$=Mid(chartest,a,1)
	; text drawn as it is supposed to do
	Text 0,40*(a+1)+00, Asc(c) : DrawImage TxtImage("(é e 1) abc "+c),45,40*(a+1)+00
	; now it works like it is supposed to do
	Text 0,40*(a+1)+20, Asc(c) : DrawImage TxtImage("(é é 1) abc "+c),45,40*(a+1)+20
Next

Flip True

WaitKey
End

Function TxtImage(txt$)
	Local r=ColorRed(), g=ColorGreen(), b=ColorBlue(), cb=GraphicsBuffer()
	Local w=HStringWidth(txt), h=HStringHeight(txt)
	Local img=CreateImage(w,h)
	SetBuffer ImageBuffer(img)
	Color 255,255,255:Rect 0,0,w,h,1
	Color 020,000,000:HText 0,0,txt,0,0
	SetBuffer cb
	Color r,g,b
	Return img
End Function

whatever, I really can't point on what is going wrong here, so I came to the conclusion :

[b]there is a bug in the Text command

Last edited 2012

_PJ_	(Posted 2012) [#3]

Am I missing something here?
I don't quite see what the bug is...

both programs (Bobysait's & Mr. Waterlily's) seem to work fine.

Yasha

(Posted 2012) [#4]

I was under the impression that Text didn't work reliably with any non-ASCII characters, and that you have to use something like FastText for that.

I'm pretty sure B3D strings don't actually support Unicode (for a start, if they did half of what I use them for wouldn't work), so any results where they get printed correctly will probably be errors luckily working out the "right" way.

_PJ_	(Posted 2012) [#5]

I think the 'problem' is not with Text, but when using commands such as Mid or Chr etc. on strings with UTF or Unicode encoding, you are specifying a single character. Blitz interprets the result as a single byte, even if it identifies the correct 'position' in a string, the value itself is still only recognised as (n And 255)

Bobysait

(Posted 2012) [#6]

nope, the truth is ... somewhere else.

Graphics 800,600,0,2
SetBuffer BackBuffer()

SetFont LoadFont("Arial",18)

DrawImage TxtImage("(é e)"),0,0
DrawImage TxtImage("(é é)"),0,20
DrawImage TxtImage("(é e 1"),0,40
DrawImage TxtImage("(é é 1"),0,60

Color 255,255,255

i=40
; text drawn as it is supposed to be drawn
Text 0,40+i+00, "a" : DrawImage TxtImage("(é e 1) abc a"),45,40+i+00
; text that does not always draw the last char (simply replacing "e" with "é")
Text 0,40+i+20, "a" : DrawImage TxtImage("(é é 1) abc a"),45,40+i+20 : i=i+40

Text 0,40+i+00, "1" : DrawImage TxtImage("(é e 1) abc 1"),45,40+i+00
Text 0,40+i+20, "1" : DrawImage TxtImage("(é é 1) abc 1"),45,40+i+20 : i=i+40

Text 0,40+i+00, "0" : DrawImage TxtImage("(é e 1) abc 0"),45,40+i+00
Text 0,40+i+20, "0" : DrawImage TxtImage("(é é 1) abc 0"),45,40+i+20 : i=i+40

Text 0,40+i+00, "(" : DrawImage TxtImage("(é e 1) abc ("),45,40+i+00
Text 0,40+i+20, "(" : DrawImage TxtImage("(é é 1) abc ("),45,40+i+20 : i=i+40

Text 0,40+i+00, ")" : DrawImage TxtImage("(é e 1) abc )"),45,40+i+00
Text 0,40+i+20, ")" : DrawImage TxtImage("(é é 1) abc )"),45,40+i+20 : i=i+40

Text 0,40+i+00, "," : DrawImage TxtImage("(é e 1) abc ,"),45,40+i+00
Text 0,40+i+20, "," : DrawImage TxtImage("(é é 1) abc ,"),45,40+i+20 : i=i+40

Text 0,40+i+00, "." : DrawImage TxtImage("(é e 1) abc ."),45,40+i+00
Text 0,40+i+20, "." : DrawImage TxtImage("(é é 1) abc ."),45,40+i+20 : i=i+40

Text 0,40+i+00, "@" : DrawImage TxtImage("(é e 1) abc @"),45,40+i+00
Text 0,40+i+20, "@" : DrawImage TxtImage("(é é 1) abc @"),45,40+i+20 : i=i+40

Text 0,40+i+00, "&" : DrawImage TxtImage("(é e 1) abc &"),45,40+i+00
Text 0,40+i+20, "&" : DrawImage TxtImage("(é é 1) abc &"),45,40+i+20 : i=i+40

Text 0,40+i+00, "é" : DrawImage TxtImage("(é e 1) abc é"),45,40+i+00
Text 0,40+i+20, "é" : DrawImage TxtImage("(é é 1) abc é"),45,40+i+20 : i=i+40

Flip True

WaitKey
End

Function TxtImage(txt$)
	Local r=ColorRed(), g=ColorGreen(), b=ColorBlue(), cb=GraphicsBuffer()
	Local w=StringWidth(txt), h=StringHeight(txt)
	Local img=CreateImage(w,h)
	SetBuffer ImageBuffer(img)
	Color 255,255,255:Rect 0,0,w,h,1
	Color 020,000,000:Text 0,0,txt,0,0
	SetBuffer cb
	Color r,g,b
	Return img
End Function

same code as above, exept it doesn't use the "chr" command. Same result.

Last edited 2012