Linepick bug (failure) on Terrain

Archives Forums/Blitz3D Bug Reports/Linepick bug (failure) on Terrain

RemiD

(Posted 2013) [#1]

Hello,

A bug which has already been discussed here :
http://blitzbasic.com/Community/posts.php?topic=73431

Linepick sometimes fails to return a pickedpickable (a mesh set as pickable), and it seems to be a problem only with terrains. See the debug infos in the example below :

Graphics3D(800,600,32,2)
SetBuffer(BackBuffer())
SeedRnd(MilliSecs())

Origine = CreateCube()
ScaleMesh(Origine,0.01/2,0.01/2,0.01/2)
EntityColor(Origine,255,000,000)

;Camera
Global Camera = CreateCamera()
CameraRange(Camera,0.1,1500)

;TerrainB3D
TerrainB3D = CreateTerrain(32)
ScaleEntity(TerrainB3D,1,25.5,1)
TerrainDetail(TerrainB3D,2048,True)
TerrainShading(TerrainB3D,True)
PositionEntity(TerrainB3D,0,0,0)
NameEntity(TerrainB3D,"TER"+Str(1))
For VX% = 0 To 31
 For VZ% = 0 To 31
  HeightRGB% = Rand(030,033)
  Height# = 1.0/255*HeightRGB
  ModifyTerrain(TerrainB3D,VX,VZ,Height,False) 
 Next
Next

;Sculpture
SculptureMesh = CreateMesh()
For GX# = 0 To 10.0 Step 1.0
 For GZ# = 0 To 10.0 Step 1.0
  TPart = CreateCube()
  SY# = Rnd(0.1,3.0)
  ScaleMesh(TPart,1.0/2,SY/2,1.0/2)
  PositionMesh(TPart,GX,SY/2,GZ)
  AddMesh(TPart,SculptureMesh)
  FreeEntity(TPart)
 Next
Next
PositionMesh(SculptureMesh,-5,0,-5)
PositionEntity(SculptureMesh,16,3.3,16)
NameEntity(SculptureMesh,"SCU"+Str(1))

SunLight = CreateLight(1)
LightColor(SunLight,225,225,225)
PositionEntity(SunLight,-1000,1000,-1000)
RotateEntity(SunLight,45,-45,0)
AmbientLight(050,050,050)

;PositionEntity(Camera,0,1.6,-3)
PositionEntity(Camera,16,3.3+1.6,0)

SPoint = CreatePivot()

Global SC#

Repeat

 MainLoopStart% = MilliSecs()

 DebugLog("")
 For i% = 1 To 1
  PositionEntity(SPoint,Rnd(0.0+0.01,32.0-0.01),1.6+15,Rnd(0.0+0.01,32.0-0.01))
  DebugLog("PointXYZ = "+Str(EntityX(SPoint,True))+","+Str(EntityY(SPoint,True))+","+Str(EntityZ(SPoint,True)))
  EntityPickMode(TerrainB3D,2)
  EntityPickMode(SculptureMesh,2)
  LinePick(EntityX(SPoint,True),EntityY(SPoint,True),EntityZ(SPoint,True),0,-100,0)
  PickedPickable = PickedEntity()
  DebugLog("PickedPickable = "+Str(PickedPickable))
  If(PickedPickable <> 0)
   DebugLog("Pick success !")
   PickedName$ = EntityName(PickedPickable)
   PickedKind$ = Left(PickedName,3)
   PickedId% = Right(PickedName,Len(PickedName)-3)
   If(PickedKind = "TER")
    TargetY# = PickedY()
    DebugLog("PickedY = "+Str(TargetY))
    TargetKind% = PickedKind
    TargetId% = 1
   ElseIf( PickedKind = "SCU" )
    TargetY# = PickedY()
    DebugLog("PickedY = "+Str(TargetY))
    TargetKind% = PickedKind
    TargetId% = 1
   EndIf
   DebugPickSuccess = CreateCube()
   ScaleMesh(DebugPickSuccess,0.025/2,0.025/2,0.025/2)
   PositionEntity(DebugPickSuccess,PickedX(),PickedY(),PickedZ())
   EntityColor(DebugPickSuccess,000,255,000)
  ElseIf(PickedPickable = 0) 
   DebugLog("Pick failure !") 
   TargetY# = 0 
   DebugLog("PickedY = "+Str(TargetY))
   TargetKind% = ""
   TargetId% = 0
   DebugPickFailure = CreateCube()
   ScaleMesh(DebugPickFailure,0.025/2,0.025/2,0.025/2)
   PositionEntity(DebugPickFailure,EntityX(SPoint,True),0,EntityZ(SPoint,True))
   EntityColor(DebugPickFailure,255,000,000)
  EndIf
  EntityPickMode(TerrainB3D,0)
  EntityPickMode(SculptureMesh,0)
 Next

 If(KeyDown(17)=1)
  MoveEntity(Camera,0,0,0.1*SC)
 ElseIf(KeyDown(31)=1)
  MoveEntity(Camera,0,0,-0.1*SC)
 EndIf
 If(KeyDown(30)=1)
  TurnEntity(Camera,0,3*SC,0)
 ElseIf(KeyDown(32)=1)
  TurnEntity(Camera,0,-3*SC,0)
 EndIf
 If(KeyDown(16)=1)
  MoveEntity(Camera,0,-0.1*SC,0)
 ElseIf(KeyDown(18)=1)
  MoveEntity(Camera,0,0.1*SC,0)
 EndIf

 If(KeyDown(2)=1)
  WireFrame(True)
 Else
  WireFrame(False)
 EndIf
 
 ClsColor(000,000,000)
 Cls()
 RenderWorld()

 Color(255,255,255)
 Text(0,0,"Triangles = "+TrisRendered())
 Text(0,20,"FPS = "+Str(FPS))

 Flip(1)

 MainLoopTime% = MilliSecs() - MainLoopStart
 If(MainLoopTime = 0)
  MainLoopTime = 1
 EndIf

 FPS% = 1000/MainLoopTime
 SC# = Float(30) / 1000 * MainLoopTime 

Until(KeyDown(1)=1)

End()

This is a major bug, i hope this will be fixed.

Thanks,

RemiD

(Posted 2014) [#2]

A solution to prevent this bug to cause weird behaviors in your app/game :
Let's say that there are a pickable terrain and pickable meshes.
Let's say that the linepick is from above to below and will go through the terrain if no others pickable meshes have been picked.
If pickedentity returns nothing, it means that the terrain should have been picked but hasn't, so what you can do in this case is to use TerrainY(StartPointX,0,StartPointZ) to find the coordinates of the picked point on the terrain which should have been picked.